Microsoft Visual Basic Version 5.0 Service Pack 2
リリース ノート

 

© 1996-1997 Microsoft Corporation

Microsoft® Visual Basic® Version 5.0 Service Pack 2 は、Visual Basic Version 5.0 Professional Edition および Enterprise Edition に対するアップデートを行います。Control Creation Edition には、同様のアップデートを提供するセットアップが別途用意されています。このアップデートにより、フォームやコントロールなどのユーザー インターフェイス要素を含む Visual Basic プロジェクトのアパートメント モデル スレッディングが可能になりました。また、Visual Basic Version 5.0 のいくつかのバグも修正されています。

Service Pack 2 を Visual Basic Version 5.0 に追加セットアップすることによって、Internet Explorer Version 4.0 のようなマルチスレッド クライアントで、よりパフォーマンスを発揮する ActiveX™ コントロールおよび ActiveX ドキュメントを作成できます。Professional Edition または Enterprise Edition に追加セットアップした場合は、次のようなプログラムも開発できるようになります。

このようなアパートメント モデル スレッディングは、Visual Basic Version 5.0 Service Pack 2 の主要な新機能です。

このリリース ノートには、Visual Basic Version 5.0 のオンライン ヘルプおよび Books Online の記載内容の補足情報も含まれています。詳細については、Microsoft Visual Basic の Web サイト、http://www.microsoft.com/vbasic/ を参照してください。

目次

アパートメント モデル スレッディングに関する変更の概要

プロジェクトのスレッド モデルの選択
アパートメント モデル スレッディング機能の制限事項
既存のプロジェクトの変換

Visual Basic Version 5.0 のドキュメントの変更点

「Visual Basic でのアパートメント モデルのスレッド」の変更点
「スレッドセーフな DLL のデザイン」の変更点
「マルチスレッドのアウトプロセス コンポーネントのデザイン」の変更点

アパートメント モデル スレッディングの使用例

Internet Explorer Version 4.0 で使用するアパートメント スレッド コントロール
フォームを持つスレッドセーフ DLL の作成
マルチスレッド テスト アプリケーションの作成

ActiveX コントロールのスクリプトの安全性に関する注意点

ファイル一覧

 

アパートメント モデル スレッディングに関する変更の概要

Visual Basic Version 5.0 Service Pack 2 では、フォームやコントロールなど、画面に表示するユーザー インターフェイス要素を含むプロジェクトにも、アパートメント モデル スレッディングを適用できます。Service Pack 2 をセットアップすることによって、フォーム、ユーザー コントロール、ユーザー ドキュメント、ActiveX デザイナがスレッドセーフになります。Service Pack 2 には次の内容が含まれます。

メモ   ActiveX デザイナのサポート コードはアパートメント モデルに対してスレッドセーフになりましたが、このことは個々のデザイナがスレッドセーフであることを必ずしも保証しません。ほかの開発元が提供しているデザイナを使用している場合は、その開発元に問い合わせてください。

Control Creation Edition の制限事項

Control Creation Edition のアップデート用セットアップは、Professional Edition および Enterprise Edition 用のセットアップとは別なので注意してください。このリリース ノートの記述で Control Creation Edition に適用されるのは、スレッドセーフ ActiveX コントロール プロジェクトに関する項目だけです。

Control Creation Edition を使用してアパートメント スレッド ActiveX コントロールを作成する場合は、コントロールのマルチスレッド動作をテストするときに Internet Explorer Version 4.0 のようなマルチスレッド クライアントを使用する必要があります。Control Creation Edition では、マルチスレッド テスト クライアントを作成することはできません。

 

プロジェクトのスレッド モデルの選択

Service Pack 2 をセットアップすると [プロジェクト プロパティ] ダイアログ ボックスの [全般] タブのオプションが変更されます。Service Pack 2 のセットアップ後は、[マルチスレッド] チェック ボックスはプロジェクトのスレッド モデルと独立して設定できるようになります。したがって、プロジェクトの [マルチスレッド] チェック ボックスをオンにしなくても、[スレッド モデル] オプションが選択できるようになります。

ActiveX DLL、ActiveX EXE、ActiveX コントロールの各プロジェクトのスレッド モデルを設定するには

  1. [プロジェクト] メニューで [<プロジェクト> のプロパティ] をクリックして [プロジェクト プロパティ] ダイアログ ボックスを開きます。
  2. [全般] タブの [スレッド モデル] ボックスでオプションを選択します。

ActiveX DLL プロジェクトおよび ActiveX コントロール プロジェクトでは、[アパートメント スレッド] と [シングル スレッド] のどちらかを選択できます。

ActiveX EXE プロジェクトでは、新しいオブジェクトが作成されるたびにそれぞれのオブジェクトが別の新しいスレッド上に作成されるようにするか ([オブジェクトごとのスレッド])、または一定個数の範囲内のスレッド上に作成されるよう制限するか ([スレッド プール])、どちらかを選択できます。スレッド プールのサイズを 1 に設定するとそのプロジェクトはシングル スレッドになり、2 以上の値に設定するとアパートメント スレッドになります。

メモ   既存のプロジェクトのスレッド モデルを変更すると、そのプロジェクトでシングル スレッドの ActiveX コントロールを使用しようとした場合に、エラーが発生します。Visual Basic ではアパートメント スレッド プロジェクトでシングル スレッド コントロールを使用できません。詳細については、「既存のプロジェクトの変換」を参照してください。

メモ   ActiveX EXE プロジェクトで [オブジェクトごとのスレッド] を選択するかスレッド プールを 2 以上に指定した場合、外部で作成されるオブジェクトだけが新しいスレッド上に作成されるようになります。詳細については、Books Online の『コンポーネント ツール ガイド』の「ActiveX コンポーネントの作成方法」の「コード コンポーネントの作成技術」の「スケーラビリティとマルチスレッド」の「マルチスレッドのアウトプロセス コンポーネントのデザイン」を参照してください。ActiveX DLL プロジェクトおよび ActiveX コントロール プロジェクトでは、スレッドの生成がクライアント アプリケーションによって制御されるので、[オブジェクトごとのスレッド] および [スレッド プール] は使用できません。

重要   Professional Edition または Enterprise Edition を使用している場合、[オブジェクトごとのスレッド] と [スレッド プール] を選択した場合のそれぞれの結果については、Books Online の『コンポーネント ツール ガイド』の「ActiveX コンポーネントの作成方法」の「コード コンポーネントの作成技術」の「スケーラビリティとマルチスレッド」の「マルチスレッドのアウトプロセス コンポーネントのデザイン」を参照してください。

Service Pack 2 と [マルチスレッド] チェック ボックス

Service Pack 2 をセットアップしても、従来の [マルチスレッド] チェック ボックスの機能自体は変更されません。[マルチスレッド] チェック ボックスをオンにすると、ネットワーク サーバー上でのユーザー インターフェイスに対する応答操作を必要とせずに実行されるコンポーネントを作成できます。Service Pack 2 で異なる点は、[マルチスレッド] チェック ボックスの設定がコンポーネントのスレッド モデルに影響しないという点です。

 

アパートメント モデル スレッディング機能の制限事項

次に示す制限は、Visual Basic のすべての Edition に対して適用されます。

 

既存のプロジェクトの変換

Visual Basic Version 5.0 Service Pack 2 をセットアップすると、既存のプロジェクトに対してアパートメント スレッディングを適用できるようになります。具体的には、「プロジェクトのスレッド モデルの選択」の記述に従って [スレッド モデル] オプションを変更し、プロジェクトを再コンパイルします。ほとんどの場合、これだけの操作でプロジェクトは正常に変換されます。

既存の ActiveX DLL、ActiveX EXE、または ActiveX コントロールのプロジェクトでシングル スレッドの内在コントロールを使用している場合は、[スレッド モデル] を [アパートメント スレッド] に変更しようとすると、エラーが発生します。シングル スレッドの ActiveX コントロールをマルチスレッド クライアントで使用すると各種の重大な問題が発生するので、Visual Basic ではシングル スレッド ActiveX コントロールをアパートメント スレッド ActiveX コンポーネント プロジェクトで使用できないようになっています。

シングル スレッド コントロールを既存のプロジェクトで使用している場合、そのコントロールのアパートメント スレッド対応版が使用可能かどうかについては、コントロールの開発元に問い合わせてください。

シングル スレッド コントロールを使用した場合に発生する問題

.vbp ファイルを手動で編集するなどの特殊な方法で、シングル スレッド コントロールをアパートメント スレッド プロジェクトで使用できるようにする手段もありますが、シングル スレッド ActiveX コントロールをアパートメント スレッド プロジェクトで使用すると、以下の問題が発生するので、そのようなことは行わないでください。

重要   マルチスレッド コンポーネントやマルチスレッド アプリケーションを Visual Basic やその他の開発ツールで作成するときにシングル スレッド コントロールを使用すると、これ以外にもさまざまな問題が発生する可能性があります。

ActiveX DLL プロジェクトおよび ActiveX コントロール プロジェクトの設計上の注意点

インプロセス コンポーネントが提供するオブジェクトはクライアント スレッド上に作成されます。DLL や OCX は、それ自体でスレッドを生成することはできません。コンポーネントが提供するオブジェクトのインスタンスをクライアント スレッドで最初に作成するとき、そのスレッドに新しいアパートメントが生成され、Sub Main が新しいアパートメントに対して実行されます。コンポーネントがそのクライアント スレッドに提供するオブジェクトはすべて、同一のアパートメントの中に作成されます。

同一クラスのすべてのインスタンスが共通のグローバル データを共有するようにコンポーネントを設計している場合、そのデータは同一のスレッド上のオブジェクト間でのみ共有されます。あるデータベースにアクセスするグローバル コードがある場合、そのアクセスはスレッドごとに独立して行われます。

たとえば、あるマルチスレッド クライアントで、Widget というコントロールの 1 つのインスタンスがスレッド A のフォーム上にあり、別の 2 つのインスタンスがスレッド B のフォーム上にあるとします。コントロールのインスタンスは 2 つのアパートメントの中にあり、それぞれグローバル変数のコピーを持つことになります。Sub Main は各アパートメントごとに 1 回ずつ実行されます。スレッド B 上の 2 つのコントロールはグローバル情報を共有しますが、これらはスレッド A 上のコントロールのグローバル情報とは独立した状態になります。

その他の設計上の注意点については、このドキュメントの「「Visual Basic でのアパートメント モデルのスレッド」の変更点」、「「スレッドセーフな DLL のデザイン」の変更点」、および Visual Basic Version 5.0 Books Online の関連項目を参照してください。

ActiveX EXE プロジェクトの設計上の注意点

アウトプロセス コンポーネントにおける、シングル スレッドとアパートメント スレッドの最も重要な相違点は、アパートメント スレッドでは、App オブジェクトのプロパティも含め、すべてのグローバル データのコピーが各スレッドごとに生成される点です。このことは、新しいスレッドが生成されるたびに Sub Main が実行されることを意味します。

アウトプロセス コンポーネントのその他の設計上の注意点については、このドキュメントの「「Visual Basic でのアパートメント モデルのスレッド」の変更点」、「「マルチスレッドのアウトプロセス コンポーネントのデザイン」の変更点」、および Visual Basic Version 5.0 Books Online の関連項目を参照してください。

 

Visual Basic Version 5.0 のドキュメントの変更点

次に示す各トピックは、Visual Basic Version 5.0 Books Online の該当個所の変更点について説明しています。

「Visual Basic でのアパートメント モデルのスレッド」の変更点
「スレッドセーフな DLL のデザイン」の変更点
「マルチスレッドのアウトプロセス コンポーネントのデザイン」の変更点

Visual Basic Professional Edition または Enterprise Edition では、Books Online の目次から以下の項目に移動すると、これらのトピックを表示できます。

『コンポーネント ツール ガイド』
  「ActiveX コンポーネントの作成方法」
    「コード コンポーネントの作成技術」
      「スケーラビリティとマルチスレッド」

メモ   Books Online は Control Creation Edition には含まれていません。ここで解説するトピックは Control Creation Edition 用にダウンロードできるドキュメントの中には含まれていません。ただし、最初の 2 つのトピックに含まれる再入に関する項目およびスレッドセーフ DLL の設計方法に関する項目は、Control Creation Edition のユーザーにとっても役に立つ情報です。

 

「Visual Basic でのアパートメント モデルのスレッド」の変更点

Books Online のこのトピックでは、スレッドごとにグローバル データのコピーが作成されると説明されています。Books Online では触れていませんが、これに伴い、Sub Main は、新しいアパートメントごとに、つまり、新しいスレッドごとに実行されます。そうする以外には、各スレッドのグローバル データを初期化する方法がないためです。詳細については、この後の「「スレッドセーフな DLL のデザイン」の変更点」および「「マルチスレッドのアウトプロセス コンポーネントのデザイン」の変更点」を参照してください。

「スレッドが使用できる箇所」の変更点

Books Online のこの項では、コンポーネントでアパートメント スレッドを使用するには、[マルチスレッド] チェック ボックスをオンにしなければならない、とありますが、Service Pack 2 ではこれは正しくありません。[マルチスレッド] チェック ボックスは [プロジェクト プロパティ] ダイアログ ボックスの [全般] タブの独立したオプションとして提供されるように変更されました。詳細については、このドキュメントの「プロジェクトのスレッド モデルの選択」を参照してください。

「再入」の変更点

Books Online のこの項では、スレッド間呼び出しを行うとき、呼び出しているメソッドでは、DoEvents 関数を呼び出すなどして制御を渡さない限り、再入は防止される、と記載されています。メソッドがスレッド間またはプロセス間でそのメソッド自体を呼び出したり、フォームを表示したりすることによっても再入が発生することに注意してください。

 

「スレッドセーフな DLL のデザイン」の変更点

Books Online のこのトピックは、ActiveX DLL プロジェクトのほか、ActiveX コントロール プロジェクトにも適用されるようになりました。

ActiveX DLL プロジェクトをアパートメント スレッドにするための手順は、「プロジェクトのスレッド モデルの選択」で説明したとおり変更されました。アパートメント スレッド DLL を作成するときに、ユーザー対話型インターフェイスを抑制する必要はなくなりました。[マルチスレッド] チェック ボックスは、従来どおり、ユーザー対話型インターフェイスの可/不可を設定しますが、スレッド モデルの設定には影響しなくなりました。

フォームのインスタンスを実行時に作成する場合、Visual Basic はほかのプライベート オブジェクトの場合と同じルールに従います。新しいフォームは、New 演算子が実行されたのと同じスレッド上に生成されます。フォームが暗黙に作成された場合、たとえば、As New Form1 と宣言された変数を使用してフォームのプロパティにアクセスした場合などは、フォームはコードが実行されたのと同じスレッド上に作成されます。

メモ   フォームの暗黙の作成の特別な点として、宣言済み ID (Form1 などの変数) があります。Visual Basic では、すべてのフォーム クラスに対し、隠されたグローバル フォーム変数が暗黙のうちに作成されます。アパートメントごとにグローバル データのコピーが作成されるので、各スレッドにそれぞれの Form1 が存在することになります。この混乱を避けるため、フォーム用の変数を明示的に宣言することによって、宣言済み ID をアパートメント スレッド コンポーネントで使用することを避けるとよいでしょう。

メモ   アパートメントごとにグローバル データのコピーが作成されるので、標準モジュール内で Public で宣言した変数はそのスレッド内でのみグローバルになり、スレッドごとにその変数のインスタンスを持つことになります。また、App オブジェクトの App.ThreadID などのプロパティも、スレッドごとに異なるインスタンスを持つことになります。

フォームと異なり、ActiveX コントロールはクライアント フォームによって生成されたり使用されたりするパブリック オブジェクトです。ActiveX コントロールのインスタンスは、常にそれを使用するクライアント フォームと同一のスレッド上に存在します。

重要   アパートメント モデル DLL では、その DLL から提供されるオブジェクトを要求するクライアント スレッドごとに新しいアパートメントが生成されます。あるクライアント スレッドがオブジェクトを最初に要求したときに、新しいアパートメントに対し Sub Main が実行されます。DLL はそれ自体のスレッドを生成することはできません。

 

「マルチスレッドのアウトプロセス コンポーネントのデザイン」の変更点

これまでは、マルチスレッドの EXE プロジェクトを作成するときに、ユーザー対話型インターフェイスを抑制することが必要でしたが、Service Pack 2 ではこれは必須ではなくなりました。つまり、[マルチスレッド] チェック ボックスをオンにしなくてもよくなりました。[オブジェクトごとのスレッド] と [スレッド プール] (複数のスレッドを巡回方式で割り当てる) に関する説明には、変更はありません。

ActiveX EXE プロジェクトをアパートメント スレッドにするには、[プロジェクト プロパティ] ダイアログ ボックスの [全般] タブで [オブジェクトごとのスレッド] をオンにするか、または [スレッド プール] を選択してプール サイズを 2 以上に設定します。

ほかのプライベート オブジェクトと同様に、フォームはそれが生成されたスレッド上に存在します。プライベート オブジェクトは CreateObject 関数で外部から作成されることがないので、新しいスレッドを生成する目的では使えません。

重要   マルチスレッド EXE プロジェクトでは、Sub Main は新しいスレッドごとに独立して実行されます。Visual Basic では、どのスレッドが最初に生成されたのかを特定することはできません。

 

アパートメント モデル スレッディングの使用例

ここでは、アパートメント モデル スレッディングが必要になる以下の 3 つの典型的な事例について解説します。

Internet Explorer Version 4.0 で使用するアパートメント スレッド コントロール
フォームを持つスレッドセーフ DLL の作成
マルチスレッド テスト アプリケーションの作成

 

Internet Explorer Version 4.0 で使用するアパートメント スレッド コントロール

Internet Explorer Version 4.0 ではウィンドウは複数の実行スレッドを使用して表示されます。Internet Explorer Version 4.0 内で 2 つの異なるウィンドウが同一の ActiveX コントロールのインスタンスを表示している場合、OCX はそれぞれのウィンドウのスレッドに対してインスタンスを提供する必要があります。これまでは、Visual Basic で作成した OCX では、両方のインスタンスが同一のアパートメントの OCX から提供されていたので、スレッド間マーシャリングが発生し、コントロールの一方のインスタンスのパフォーマンスが低下する原因となっていました。

パフォーマンスの低下のほか、シングル スレッド コントロールをマルチスレッド アプリケーション内で使用すると、フォーカス、タブ移動、アクセス キーに関連する問題が発生する可能性もあります。

OCX を Visual Basic Version 5.0 Service Pack 2 でコンパイルすることによって、パフォーマンスを改善し、これらの問題点を解決することができます。OCX は、クライアント スレッドごとに独立したアパートメントをサポートするようになるので、Internet Explorer Version 4.0 で使用される各コントロールのインスタンスは、そのコントロールを表示するウィンドウと同じスレッド上で実行されます。

Visual Basic に付属の大部分の ActiveX コントロールのアパートメント スレッド対応版

Visual Basic Version 5.0 Service Pack 2 では、Visual Basic Version 5.0 に含まれていた大部分の ActiveX コントロールの新バージョンが提供されました。更新されたコントロールはアパートメント モデル スレッド対応であり、シングル スレッド クライアントでもマルチスレッド クライアントでも適切に動作します。ただし、DB グリッド (DBGrid) コントロール、チャート (MSChart) コントロール、および Visual Basic Version 5.0 の \Tools.jpn\controls ディレクトリで提供されていたコントロールのアパートメント スレッド対応版は含まれていません。

Visual Basic で作成した ActiveX コントロール

Visual Basic Version 5.0 Service Pack 2 をセットアップすると、新規作成する ActiveX コントロール プロジェクトは、特に指定しない限りアパートメント モデル スレッディングになります。既存の ActiveX コントロール プロジェクトにアパートメント モデル スレッディングを追加するには、「プロジェクトのスレッド モデルの選択」で述べたようにスレッド モデルを変更し、プロジェクトを再コンパイルします。ほとんどの ActiveX コントロール プロジェクトの場合、これだけの操作で正常に変換されます。

ActiveX コントロール プロジェクトでシングル スレッドの内在コントロールを使用している場合は、[スレッド モデル] を [アパートメント スレッド] に変更しようとすると、エラーが発生します。シングル スレッドの ActiveX コントロールをマルチスレッド クライアントで使用すると、各種の重大な問題が発生するので、Visual Basic ではシングル スレッド ActiveX コントロールをアパートメント スレッド ActiveX コントロールの内在コントロールとして使用できないようになっています。詳細については、「既存のプロジェクトの変換」を参照してください。

既存の ActiveX コントロール プロジェクトでシングル スレッドの内在コントロール使用している場合、そのシングル スレッド コントロールのアパートメント スレッド対応版が使用可能かどうかについては、コントロールの開発元に問い合わせてください。

アパートメント スレッド ActiveX コントロールに関するその他の設計上の注意点については、「既存のプロジェクトの変換」を参照してください。

 

フォームを持つスレッドセーフ DLL の作成

フォームを持つ ActiveX DLL プロジェクトでも、[スレッド モデル] オプションを [アパートメント スレッド] に設定できるようになりました。

アパートメント スレッド DLL はそれ自体でスレッドを生成することができません。クライアント スレッドが、その DLL から提供されるオブジェクトを最初に要求したときに、新しいアパートメントが生成され、そのアパートメントに対し Sub Main が実行されます。そのクライアントが要求するパブリック オブジェクトはすべて、同一のアパートメントの中に存在し、グローバル データを共有します。このようなパブリック オブジェクトによって作成されるフォームなどのプライベート オブジェクトもすべて、同一のアパートメントの中に存在します。

Visual Basic では、あるアパートメントがほかのアパートメントを認識する手段を提供していません。ただし、マルチスレッド クライアントが、スレッド A 上のオブジェクトへの参照を取得してそれをスレッド B 上のオブジェクトに渡すことができるようにすることはできます。このようなことができるように DLL を設計する場合、Books Online の『コンポーネント ツール ガイド』の「コード コンポーネントの作成技術」の「スケーラビリティとマルチスレッド」の「Visual Basic でのアパートメント モデルのスレッド」、およびこのドキュメントの「「Visual Basic でのアパートメント モデルのスレッド」の変更点」の再入に関する項を参照してください。

重要   スレッドから表示されるモーダル フォームはほかのスレッド上のコードの実行をブロックせず、ほかのスレッド上のフォームに対してはモーダルになりません。フォームを表示すると、DoEvents 関数を呼び出す場合と同様に、コントロールに制御が渡され、この結果、オブジェクトのコードへの再入が発生する場合があります。

 

マルチスレッド テスト アプリケーションの作成

Visual Basic Professional Edition および Enterprise Edition に Service Pack 2 をセットアップすると、マルチスレッド コントロールをテストするためのマルチスレッド アプリケーションを作成できるようになります。簡単なマルチスレッド アプリケーションの作成手順は以下のとおりです。

  1. ActiveX EXE プロジェクトを新規作成して、既定で作成されるクラス モジュールの名前を MainApp に変更します。MainApp の Instancing プロパティを PublicNotCreatable に設定します。MainApp オブジェクトはそのアプリケーションの 1 つ目のスレッドを使用してメイン ユーザー インターフェイスを表示します。
  2. [プロジェクト プロパティ] ダイアログ ボックスの [全般] タブを開き、[スレッド モデル] ボックスで [オブジェクトごとのスレッド] を選択して、[プロジェクト名] に重複しない名前を入力します。[プロジェクト名] はタイプ ライブラリ名となります。複数のアプリケーションが同じタイプ ライブラリ名を持っていると問題が発生するので注意してください。この例ではプロジェクト名として "ThreadDemo" を使用します。[コンポーネント] タブの [スタート モード] では [独立型] を選択します。
  3. フォーム モジュールを追加して frmProcess という名前を設定し、Visible プロパティと ControlBox プロパティを False に設定します。このフォームは、Sub Main がプロセスのメイン スレッドを識別するための非表示のウィンドウとして使用されます。このフォームにはコードは記述しません。
  4. 標準モジュールをプロジェクトに追加します。このモジュールでは、宣言、Sub Main プロシージャ、EnumThreadWndMain プロシージャを記述します。この後の手順とコード内のコメントで説明するとおり、Sub Main は、アプリケーションの開始時およびスレッドが新規作成されるたびに実行されます。Sub Main のサンプル コードでは、最初のスレッドを識別する方法を示します。これによって、MainApp オブジェクトをいつ作成すべきかを判断できます。
  5. フォーム モジュールを追加して frmMTMain という名前を設定します。このフォームはテスト アプリケーションのメイン ユーザー インターフェイスを提供します。このフォームには、1 行の宣言と Form_Unload イベント プロシージャを記述します。このコードの例は、この後の「テスト アプリケーションの複数のインスタンス」の項の直前にあります。
  6. MainApp の Class_Initialize イベント プロシージャに、frmMTMain を表示するコードを追加します。記述するコードはこの後に掲載されています。
  7. 追加のテスト スレッドを生成するために、Instancing プロパティが MultiUse に設定されたクラスをプロジェクト内に少なくとも 1 つ追加する必要があります。クラス モジュールとフォーム モジュールを追加し、この後の「新しいスレッドの生成」に掲載したコードを入力します。このプロジェクトでは [オブジェクトごとのスレッド] をオンにしているので、外部で作成される各パブリック オブジェクトは新しいスレッド上で開始されます。つまり、CreateObject 関数で MultiUse 設定のクラスのインスタンスをプログラム ID から作成することによって、新しいスレッドを生成できます。詳細については、この後の項で説明します。
  8. 定義した MultiUse 設定のクラスのインスタンスを生成することによって新しいスレッドを生成するコードを、frmMTMain に追加します。このコードの例は、「新しいスレッドの生成」にあります。
  9. 開発環境はマルチスレッディングをサポートしません。F5 キーを押してプロジェクトを実行しても、すべてのプロジェクトは同一のスレッド上に生成されます。マルチスレッドの動作をテストするには、ActiveX EXE プロジェクトをコンパイルし、生成された実行可能ファイルを実行します。

重要   MultiUse 設定のオブジェクトを新しく作成するたびに新しいスレッドが確実に生成されるようにするには、[スレッド プール] ではなく [オブジェクトごとのスレッド] を使用します。

Sub Main でのメイン スレッドの識別

Sub Main はスレッドが新規作成されるたびに実行されます。これは、Visual Basic がグローバル データのコピーを各スレッド (各アパートメント) ごとに独立して保持するためです。各スレッドのグローバル データを初期化するために、Sub Main を実行する必要があります。したがって、Sub Main で非表示フォームをロードしたりアプリケーションのメイン ユーザー インターフェイスを表示したりする場合は、スレッドが新規作成されるたびに、このようなフォームの新しいコピーがロードされることになります。

以下に示すコードでは、Sub Main が実行されているのが最初のスレッド上かどうかを調べて、非表示フォームを最初の 1 回だけロードし、テスト アプリケーションのユーザー インターフェイスを 1 回だけ表示するようにしています。

' 非表示ウィンドウのキャプションに使用する文字列
Public Const PROC_CAPTION = "ApartmentDemoProcessWindow"

Public Const ERR_InternalStartup = &H600
Public Const ERR_NoAutomation = &H601

Public Const ENUM_STOP = 0
Public Const ENUM_CONTINUE = 1

Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Declare Function EnumThreadWindows Lib "user32" (ByVal dwThreadId As Long, ByVal lpfn As Long, ByVal lParam As Long) As Long

' EnumThreadWindows 関数によって取得するウィンドウ ハンドル
Private mhwndVB As Long
' メイン スレッドを識別するために使用する非表示フォーム
Private mfrmProcess As New frmProcess
' プロセス ID
Private mlngProcessID As Long

Sub Main()
    Dim ma As MainApp

    ' プロセス ID を取得するためにウィンドウ ハンドルを利用します。
    ' 後の EnumThreadWndMain コールバック関数を参照してください。
    Call EnumThreadWindows(App.ThreadID, AddressOf EnumThreadWndMain, 0&)
    If mhwndVB = 0 Then
        Err.Raise ERR_InternalStartup + vbObjectError, , "スレッドを開始するときに内部エラーが発生しました。"
    Else
        Call GetWindowThreadProcessId(mhwndVB, mlngProcessID)
        ' 非表示ウィンドウのキャプションの末尾にプロセス ID を追加します。
        If 0 = FindWindow(vbNullString, PROC_CAPTION & CStr(mlngProcessID)) Then
            ' ウィンドウが見つからないので、これが最初のスレッドです。
            If App.StartMode = vbSModeStandalone Then
                ' 固有のキャプションを持つ非表示フォームを作成します。
                mfrmProcess.Caption = PROC_CAPTION & CStr(mlngProcessID)
                ' MainApp の Initialize イベントでメイン ユーザー インターフェイスを表示します。 
                ' MainApp の Instancing プロパティは PublicNotCreatable に設定されています。
                Set ma = New MainApp
                ' (MainApp へのグローバルな参照がない場合は、アプリケーションの
                '   終了はより単純になります。ただし、MainApp が終了してしまわな
                '   いようにするために、MainApp からメイン ユーザー フォームに
                '   Me 参照を引き渡しておく必要があります。)
            Else
                Err.Raise ERR_NoAutomation + vbObjectError, , _
                    "このアプリケーションは、オートメーションで開始することができません。"
            End If
        End If
    End If
End Sub

' EnumThreadWindows によって使用されるコールバック関数
Public Function EnumThreadWndMain(ByVal hwnd As Long, ByVal lParam As Long) As Long
    ' ウィンドウ ハンドルを保存します。
    mhwndVB = hwnd
    ' ウィンドウ ハンドルが必要となるのは、最初のウィンドウだけです。
    ' ウィンドウが見つかったらこの処理を中止します。
    EnumThreadWndMain = ENUM_STOP
End Function

' MainApp の Terminate イベントの中で呼び出される Sub プロシージャです。
'   これを呼び出さないと、非表示フォームへの参照が残っているために
'   アプリケーションが終了できなくなってしまいます。
Public Sub FreeProcessWindow()
    Unload mfrmProcess
    Set mfrmProcess = Nothing
End Sub

重要   最初のスレッドを識別するためのこのような手法は、Visual Basic の将来のバージョンでは使用できない可能性があるので注意してください。

この例では、Sub Main は 2 番目以降のスレッドに対して何も処理を実行しないことに注意してください。MultiUse 設定のオブジェクトを作成するコードを、別の新しいスレッドを開始するために追加する場合、それらのオブジェクトを初期化するコードも必ず追加してください。

EnumThreadWindows 関数は、内部的に使用する非表示ウィンドウの 1 つを識別するための EnumThreadWndMain コールバック関数と一緒に使用されています。この非表示ウィンドウのウィンドウ ハンドルが GetWindowThreadProcessId 関数に引き渡され、この関数からプロセス ID が返されます。プロセス ID は、Sub Main でロードする非表示ウィンドウ (frmProcess) の固有のキャプションを作成するのに使用されます。これ以降に生成されるスレッドではこのウィンドウを検出することによって、MainApp オブジェクトを作成する必要がないことを判断できます。Visual Basic ではアプリケーションのメイン スレッドを識別する手段が提供されていないので、スレッドが作成されるたびにこのような処理を実行することが必要になります。

MainApp クラスの Initialize イベントでは、テスト アプリケーションのメイン フォームを表示します。MainApp から Me 参照をメイン フォームに引き渡すことによって、MainApp が終了しないようにすることができます。メイン ユーザー インターフェイスからすべての後続のスレッドを生成できます。MainApp の Instancing プロパティを PublicNotCreatable に設定すると、メイン ユーザー インターフェイスを 2 つ以上表示するのを避けることができます。

MainApp クラスとその関連フォームの簡単な例を次に示します。前述の手順 5 および 6 に該当します。

' MainApp クラスのコード
Private mfrmMTMain As New frmMTMain

Private Sub Class_Initialize()
    Set mfrmMTMain.MainApp = Me
    mfrmMTMain.Caption = mfrmMTMain.Caption & " (" & App.ThreadID & ")"
    mfrmMTMain.Show
End Sub

Friend Sub Closing()
    Set mfrmMTMain = Nothing
End Sub

Private Sub Class_Terminate()
    ' 非表示ウィンドウを消去します。
    Call FreeProcessWindow
End Sub

' frmMTMain フォームのコード
Public MainApp As MainApp

Private Sub Form_Unload(Cancel As Integer)
    Call MainApp.Closing
    Set MainApp = Nothing
End Sub

テスト アプリケーションの複数のインスタンス

非表示ウィンドウのキャプションにそれぞれのプロセス ID を含めることによって、テスト アプリケーションの複数のインスタンスを、競合させずに動作させることができます。

CreateObject 関数を呼び出すと、パブリック クラスのインスタンスは現在のアプリケーション インスタンスのスレッド上に作成されます。これは、CreateObject 関数が、オブジェクトを提供する可能性があるほかの実行中の Exe コンポーネントを探す前に、常に現在のアプリケーションにオブジェクトを作成しようとするためです。

アパートメントでの使用に便利なプロパティ

Sub Main を含むモジュールの取得専用プロパティとしてプロセス ID を公開しておくと便利です。

' このコードはテスト アプリケーションに必須のコードではありません。
Public Property Get ProcessID() As Long
    ProcessID = mlngProcessID
End Property

これにより、そのスレッド上のどのオブジェクトも、対象を指定せずに ProcessID プロパティを参照することでプロセス ID を取得できます。同じ方法で、ブール型 (Boolean) の IsMainThread プロパティを公開すると便利です。

新しいスレッドの生成

[オブジェクトごとのスレッド] オプションを選択すると、外部で作成された、つまり、CreateObject 関数を使用して作成されたパブリック オブジェクトは、新しいスレッド上で開始されます。MultiUse 設定のクラスのプログラム ID (ProgID) を使用することによって、簡単に新しいスレッドを生成できます。

' このコードはテスト アプリケーションの一部ではありません。
Dim tw As ThreadedWindow
Set tw = CreateObject("ThreadDemo.ThreadedWindow")

変数 tw には、新しいスレッド上のオブジェクトへの参照が含まれます。tw を使用してこのオブジェクトのプロパティまたはメソッドを呼び出すたびに、スレッド間マーシャリングの負荷がかかることになります。

メモ   New 演算子で作成されるオブジェクトは、新しいスレッド上には作成されず、New 演算子が実行されたのと同一のスレッド上に存在します。詳細については、Books Online の『コンポーネント ツール ガイド』の「ActiveX コンポーネントの作成方法」の「コード コンポーネントの作成技術」の「スケーラビリティとマルチスレッド」の「マルチスレッドのアウトプロセス コンポーネントのデザイン」および「Visual Basic のコンポーネントでのオブジェクト作成の説明」を参照してください。

MainApp が、ほかのスレッドが終了するまでは終了されないことを確実にするには、各パブリック クラスに MainApp プロパティを設定します。MultiUse 設定のオブジェクトを新しいスレッド上に作成するとき、初期化処理の一部として MainApp オブジェクトへの参照を新しいオブジェクトに引き渡します。同様に、新しいオブジェクトへの参照を MainApp に引き渡して、スレッドを制御するすべてのオブジェクトへの参照を MainApp でまとめて保持することもできますが、この場合は循環参照の問題が発生する可能性があります。詳細については、Books Online の『コンポーネント ツール ガイド』の「ActiveX コンポーネントの作成方法」の「コンポーネント設計の基本概念」の「オブジェクトの構成: オブジェクト モデル」の「循環参照の取り扱い」を参照してください。

スレッドを制御するクラスでフォームを表示する場合、Initialize メソッド (Initialize イベントではありません) または Show メソッドなどを作成してそこでフォームを表示するようにする必要があります。フォームの表示を Class_Initialize イベント プロシージャで行わないでください。Initialize イベントでフォームを表示すると、そのクラスのインスタンスを作成するときにタイミング エラーが発生します。非常に簡単な例として、MultiUse の ThreadedWindow というクラスと、そのフォーム frmThreadedWindow のコードを以下に示します。

' MultiUse 設定の ThreadedWindow クラスのコード
Private mMainApp As MainApp
Private mfrm As New frmThreadedWindow

Public Sub Initialize(ByVal ma As MainApp)
    Set mMainApp = ma
    Set mfrm.ThreadedWindow = Me
    mfrm.Caption = mfrm.Caption & " (" & App.ThreadID & ")"
    mfrm.Show
End Sub

Friend Sub Closing()
    Set mfrm = Nothing
End Sub

'フォーム frmThreadedWindow のコード
Public ThreadedWindow As ThreadedWindow

Private Sub Form_Unload(Cancel As Integer)
    Call ThreadedWindow.Closing
    Set ThreadedWindow = Nothing
End Sub

次に示すコードは、 ThreadedWindow オブジェクトの初期化方法を示します。

'テスト アプリケーションのメイン フォーム (frmMTMain) のコード
Private Sub mnuFileNewTW_Click()
    Dim tw As ThreadedWindow
    Set tw = CreateObject("ThreadDemo.ThreadedWindow")
    ' 新しいオブジェクトでフォームを表示させ、
    '   メイン アプリケーション オブジェクトへの参照を
    '   引き渡します。
    Call tw.Initialize(Me.MainApp)
End Sub

スレッドを制御できるクラスが複数ある場合は、Initialize メソッドを含む IApartment インターフェイスを定義することによって、コードをより汎用的にすることができます。IApartment を各クラスに定義するとき、各クラスに応じた Initialize メソッドのコードを提供できます。スレッド生成用のコードは次のようになります。

' このコードはテスト アプリケーションに必須のコードではありません。
Private Sub mnuFileNewObject_Click(Index As Integer)
    Dim iapt As IApartment
    Select Case Index
      Case otThreadedWindow
        Set iapt = CreateObject("ThreadDemo.ThreadedWindow")
      ' (ほかの Case ステートメント省略)
    End Select
    ' オブジェクトを初期化する共通のコード
    Call iapt.Initialize(MainApp)
End Sub

メモ   別のタイプ ライブラリに IXxxxApartment インターフェイスを定義することによって、マルチスレッド アプリケーションに対してだけ公開される IXxxxApartment インターフェイスを作成することができます。ActiveX EXE プロジェクトでは、そのタイプ ライブラリへの参照を設定します。

スレッドを制御するオブジェクトへの参照の保持

マルチスレッド アプリケーションを正常に終了するには、スレッドの生成や制御に使用する MultiUse 設定のオブジェクトへのすべての参照を注意して追跡する必要があります。

オブジェクトの有効期間は、明確に定める必要があります。たとえば、フォームを表示する MultiUse 設定のオブジェクトの場合を考えます。オブジェクトの有効期間を管理する最も簡単な方法は、オブジェクトからフォームに Me 参照を引き渡すことです。このフォームによって、オブジェクトを実行中の状態に保持できます。ユーザーがこのフォームを閉じるとき、そのフォームの Unload イベントで MultiUse 設定のオブジェクトへのすべての参照を Nothing に設定し、これによって、オブジェクトの終了およびフォームへの参照の解放も可能になります。MultiUse 設定のオブジェクトに Friend メソッドを設定し、その中でフォームおよびその他のすべての内部オブジェクトへの参照をクリアするようにしても便利です。フォームの Unload イベントでこのメソッドを呼び出すことができます。

スレッドを制御するオブジェクトが New 演算子を使用してスレッド上に別のオブジェクトを作成した場合、それらのオブジェクトへの参照を必ずクリアするようにしてください。スレッドは、そのスレッド上に作成されたオブジェクトへの参照がすべて解放されるまでは閉じられません。スレッドを開いておくことは、システム リソースを消費します。

Friend メンバはスレッド間で使えない

Friend プロパティとメソッドはクラスのパブリック インターフェイスではないので、ほかのスレッドから呼び出すことはできません。オブジェクト間でスレッドを越えて呼び出すことができるのは、Public に宣言されたプロパティおよびメソッドに限られます。

再入

あるオブジェクトのメソッドで、DoEvents 関数を呼び出したり、モーダル フォームを表示したり、ほかのスレッドのオブジェクトを複数回呼び出したりして、制御が渡された場合、メソッド内のコードは最初の呼び出しが完了する前に次の呼び出しを処理する可能性があります。このようなメソッドがプロパティの値やモジュール レベルの変数を使ったり変更したりすると、オブジェクトの内部状態が不正になります。再入を回避するには、次の方法があります。

非同期のタスク

Visual Basic では、あるスレッドが新しいスレッド上でのメソッドの呼び出しを開始し、すぐに元のスレッドでの処理を再開するというような、非同期処理の手段を提供していません。このような処理をテスト アプリケーションにおいてシミュレートするには、メソッドの呼び出しでタイマーを起動して、すぐに制御を返すようにします。タイマー イベントが発生したら、タイマーをオフにして非同期処理を実行します。このテクニックについては、Books Online の『コンポーネント ツール ガイド』の「ActiveX コンポーネントの作成方法」の「コード コンポーネントの作成技術」の「非同期コールバックとイベント」を参照してください。具体例については、Books Online の『コンポーネント ツール ガイド』の「ActiveX EXE コンポーネントの作成手順」および Coffee サンプル アプリケーションを参照してください。

マルチスレッド テスト アプリケーションの使用

現在の Visual Basic の開発環境では、マルチスレッドによる実行はサポートされていないので、アパートメント スレッド コンポーネントをテストするには、マルチスレッド テスト アプリケーションをコンパイルする必要があります。Visual Studio を使用している場合は、テスト アプリケーションをネイティブ コード デバッグ用のデバッグ情報付きでコンパイルして、Visual Studio デバッガが使用できるようにすることもできます。

 

ActiveX コントロールのスクリプトの安全性に関する注意点

Visual Basic Version 5.0 Service Pack 2 に含まれるアパートメント スレッド対応版コントロールのうち、コモン ダイアログ (CommonDialog) コントロールおよびツール バー (Toolbar) コントロールが ActiveX IObjectSafety インターフェイスをサポートするようになりました。これらのコントロールを Internet Explorer のようにスクリプト記述の安全性を必要とする環境で使用した場合、スクリプト化の安全性保持がマークされますが、安全性を保証するために、これらのコントロールの機能の一部は使用できなくなります。

 

ファイル一覧

Visual Basic Version 5.0 Service Pack 2 には以下に示すファイルが含まれています。 

asycfilt.dll
c2.exe
cmctljp.dll
cmdlgjp.dll
comct232.dep
comct232.ocx
comctl32.dep
comctl32.ocx
comdlg32.dep
comdlg32.ocx
dbgrid32.dep
dbgrid32.ocx
dblist32.dep
dblist32.ocx
flxgdjp.dll
mci32.dep
mci32.ocx
mscdrun.dep
mscdrun.dll
mscomm32.dep
mscomm32.ocx

mscondes.dll
msflxgrd.dep
msflxgrd.ocx
msinet.dep
msinet.ocx
msmapi32.dep
msmapi32.ocx
msmask32.dep
msmask32.ocx
msprpjp.dll
msrdc20.dep
msrdc20.ocx
msrdo20.dep
msrdo20.dll
msstkprp.dll
msvbvm50.dll
mswinsck.dep
mswinsck.ocx
oleaut32.dll
olepro32.dll
picclp32.dep

picclp32.ocx
readme.wri
richtx32.dep
richtx32.ocx
setup1.bas
setup1.exe
setupwiz.exe
stdole2.tlb
sysinfo.dep
sysinfo.ocx
tabctl32.dep
tabctl32.ocx
vb5.exe
vb5dep.ini
vb5ide.dll
vb5jp.dll
vb5sp2.htm
vb5sp2.wri
vba332me.dll
vba5.dll