Microsoft Visual Basic Version 5.0 SP2 產品說明

 

© 1996-1997 Microsoft Corporation

Visual Basic Version 5.0 SP2 是 Visual Basic 專業版、企業版和 Control Creation Edition 的更新版。它使得 Visual Basic 專案具備了公寓模型執行緒(Apartment-Model Thread)的能力,而這些專案通常包括了使用者介面元素,像表單和控制項等。同時,此更新版也修正了 Visual Basic 5.0 中被發現的若干錯誤。(您可在 Knowledge Base Web 站台上搜尋 VB5FixListSP,以得知被更正的錯誤。此網站位於 http://www.microsoft.com/kb/default.asp。)

加裝 Service Pack 2 到您已安裝的 Visual Basic,將可以使您所建立的 ActiveX&trade 控制項和 ActiveX 文件,得以在多執行緒客戶端(如 Internet Explorer 4.0)順利地執行。如果您有 Visual Basic 的專業版或企業版,您可以建立:

Visual Basic 5.0 SP 2 的唯一新增特色,便是強化公寓模型執行緒的功能。

本產品說明包括了 Microsoft® Visual Basic® 5.0 在輔助說明和線上手冊技術文件中的補充資訊。欲查詢其它的資訊,請到 Microsoft Visual Basic Web 站台: http://www.microsoft.com/vbasic/。

內容

概觀公寓模型執行緒的變動

為您的專案選擇執行緒模型
公寓模型執行緒功能的限制
轉換現有的專案

Visual Basic 5.0 技術文件的變動

"Visual Basic 的公寓模型執行緒"的變動
"設計 Thread-Safe DLLs"的變動
"設計多執行緒跨處理序元件"的變動

使用實例

Internet Explorer 4.0 中的公寓模型執行緒控制項
以表單建立 Thread-Safe DLL
建立多執行緒測試應用程式

Script 中 ActiveX 控制項的使用安全性說明

包裝清單

 

概觀公寓模型執行緒的變動

以 Visual Basic Version 5.0 SP2 開發專案,可以充分利用公寓模型執行緒(Apartment-model Threading),而無須犧牲如表單和控制項等視覺化的成員。應用 Service Pack 2 可使表單、使用者控制項(UserControl)、使用者文件(UserDocument)和 ActiveX 設計師具備執行緒安全(Thread-safe)的特性。Service Pack 2 包括:

請注意   ActiveX 設計師所提供的支援程式碼,已具備公寓模型的執行緒安全性;但不代表其它的設計師也有此特性。如果您使用的是協力廠商所設計的 ActiveX 設計師,請與該廠商確認此點。

Control Creation Edition 5.0 版的限制

在此技術文件中惟一應用於 Control Creation Edition 的部份,是那些有關 ActiveX 控制項專案中執行緒安全的部分。

如果您使用 Control Creation Edition 來建立公寓模型執行緒 ActiveX 控制項,您必須使用如 Internet Explorer 4.0 的多執行緒客戶端來測試控制項的多執行緒行為。您無法使用 Control Creation Edition 來建立一個多執行緒的測試客戶端。

 

為您的專案選擇執行緒模型

Service Pack 2 更動了「專案屬性」對話方塊的「一般」頁籤中的選項。在您安裝了 Service Pack 2 後,原先的「執行時無使用者介面」選項,將不再對您專案的執行緒模型有所影響。也就是說,您可以選擇設定「執行緒模組」 選項,而不用以「執行時無使用者介面」來製作您的專案。

設定 ActiveX DLL、ActiveX 執行檔或 ActiveX 控制項等專案的執行緒模型

  1. 在「專案」功能表,按<某專案名稱>屬性來開啟專案屬性對話方塊。
  2. 在一般的頁籤畫面中,於執行緒模型方塊選擇想要的選項。

對於 ActiveX DLL 和 ActiveX 控制項專案,您可以選擇公寓模型執行緒或單一執行緒。

對於 ActiveX Exe 專案,你可以指定在新的執行緒中建立每個新物件 (獨立的執行緒),或限制您的元件使用大小固定的執行緒共用區。執行緒共用區大小為一的專案即是單一執行緒;而執行緒共用區大小超過一的專案即為公寓模型執行緒。

請注意   若您對已存在的專案改變執行緒模型,如果專案中使用了單一執行緒的 ActiveX 控制項,將會發生錯誤。Visual Basic 禁止使用者在公寓模型執行緒專案中,使用單一執行緒的控制項,請參閱 轉換現有的專案。

請注意   當您針對 ActiveX 執行檔專案指定「獨立的執行緒」(或大於一的執行緒共用區),只有 外部建立(externally created) 的物件會被建立在新的執行緒上。(請參閱線上手冊的"設計多執行緒跨處理序元件"。)對於 ActiveX DLL 和 ActiveX 控制項專案,「獨立的執行緒」和執行緒共用區是無法適用的,因為執行緒的建立是由客戶端的應用程式所控制。

重要   對於專業版和企業版的使用者,線上手冊中的"設計多執行緒跨處理序元件"一文中,有選擇「獨立的執行緒」或執行緒共用區的討論。

Service Pack 2 和「執行時無使用者介面」

Service Pack 2 並沒有改變「執行時無使用者介面」選項的功能。「執行時無使用者介面」仍然允許您來建立執行時無須使用者監控的元件。Service Pack 2 惟一的改變是,選擇「執行時無使用者介面」不會影響元件的執行緒模型。

 

公寓模型執行緒功能的限制

以下的限制適用於所有 Visual Basic 的版本。

 

轉換現有的專案

一旦您安裝了 Visual Basic Version 5.0 SP2,您可以利用改變「執行緒模型」選項,來為以前專案增加公寓模型執行緒的功能;請參閱為您的專案選擇執行緒模型中所描述的步驟,然後再重新編譯一次專案。對許多專案而言,您只要執行這些動作即可。

如果某現存的 ActiveX DLL、ActiveX 執行檔或 ActiveX 控制項專案中,使用了單一執行緒控制項,若您企圖去改變執行緒模型為公寓模型執行緒將會導致錯誤。由於單一執行緒 ActiveX 控制項會使得多執行緒客戶端發生許多嚴重的問題,Visual Basic 不允許它們被使用在 ActiveX 元件專案中。

如果您的專案使用了單一執行緒控制項,請連絡經銷商詢問是否可取得公寓模型執行緒的版本。

面對單一執行緒控制項的使用

透過自行編輯 Visual Basic 的 .vbp 檔,有可能在公寓模型執行緒的專案中使用單一執行緒控制項。但請不要嚐試這樣做。因為單一執行緒 ActiveX 控制項可能會導致下列問題:

重要   單一執行緒控制項在多執行緒元件中所導致的種種許多問題,不管使用 Visual Basic 或其它開發工具,都會發生。

ActiveX DLL 和 ActiveX 控制項專案的設計考量

同處理序元件所提供的物件乃在客戶端執行緒上所建立的;換言之,您的 DLL 或 OCX 不能建立它自己的執行緒。當客戶端執行緒第一次建立由您元件所提供的物件個體時,一個新的「公寓」將會被建立於該執行緒中,您的 Sub Main 主程式將會為該「公寓」而執行。而您元件為客戶端執行緒所提供的所有物件,將「居住」於此「公寓」中。

如果您元件的設計方式是同一物件類別的執行個體會共用某些全域(global)資料,則這些資料只會被在相同執行緒上的物件所共用。如果您有撰寫存取資料庫的全域程式碼,則這些存取動作將會分別發生在每一個執行緒中。

舉例來說,假如某多執行緒客戶端會在執行緒 A 的表單中,顯示一個 Widget 控制項的執行個體,且在執行緒 B 的表單中顯示另外二個執行個體。這些控制項的執行個體將處於二個「公寓」中, 每一個「公寓」都會有一份您的全域變數。每一個「公寓」也將會分別執行 Sub Main 主程式。執行緒 B 的二個控制項將會共用同一份全域資料,此全域資料與執行緒 A 控制項的全域資料是毫不相關的。

其它相關的設計考量可參閱"Visual Basic 的公寓模型執行緒"的變動 和 "設計 Thread-Safe DLLs"的變動,以及 Visual Basic 5.0 線上手冊的相關主題。

ActiveX 執行檔專案的設計考量

單一執行緒和公寓模型執行緒跨處理序元件之間最重要的不同,是所有的全域資料(包括 App 物件的屬性)都被複寫於每一個執行緒中。這意味著每當一個新的執行緒被建立時, Sub Main 主程式就會執行一次。

其它相關的設計考量可參閱"Visual Basic 的公寓模型執行緒"的變動 和 "設計多執行緒跨處理序元件"的變動,以及 Visual Basic 5.0 線上手冊的相關主題。

 

Visual Basic 5.0 技術文件的變動

以下的主題,明確地指出 Visual Basic 5.0 線上手冊所需改變的內容:

"Visual Basic 的公寓模型執行緒"的變動
"設計 Thread-Safe DLLs"的變動
"設計多執行緒跨處理序元件"的變動

如果您有 Visual Basic 的專業版和企業版,您可以在線上手冊的內容窗格中尋找以下主題:

元件工具指南
  建立 ActiveX 元件
    建立程式碼元件
      可均分性與多執行緒

請注意   線上手冊瀏覽器不包括在 Control Creation Edition 中。以上主題也不包括在可供 Control Creation Edition 使用者下載的 Visual Basic 5.0 技術文件中。然而,以下二個主題中有關「再次呼叫進入(Reentrancy)」和設計具執行緒安全性之 DLL 的內容,將會令 Control Creation Edition 的使用者感到興趣。

 

"Visual Basic 的公寓模型執行緒"的變動

原先線上手冊中的主題解釋了 Visual Basic 對每一個執行緒,皆維持獨立而完整的全域資料。而線上手冊沒有提到的邊際效應是對每一個新的「公寓」(即新的執行緒),Sub Main 主程式都會執行一次。否則,將無法對該執行緒的全域資料做初始化的動作。以下的 "設計 Thread-Safe DLLs"的變動 和 "設計多執行緒跨處理序元件"的變動中有進一步的討論。

那裡可以使用執行緒

您不再需要為了使用公寓模型執行緒,而使得元件被標示為「執行時無使用者介面」。安裝 SP2 後,「執行時無使用者介面」在「專案屬性」對話方塊的「一般」頁籤中已成為獨立的選項,就像在為您的專案選擇執行緒模型 中所描述的。

再次呼叫進入(Reentrancy)

原先的主題陳述當您要製作跨執行緒呼叫時,您所呼叫的方法將被保護著不再被重覆進入,除非該方法讓出執行權(例如:呼叫 DoEvents)。現在請注意,就是藉由跨執行緒或跨處理序來呼叫它自己或是顯示表單,也可讓方法讓出執行權。

 

"設計 Thread-Safe DLLs"的變動

此線上手冊主題可適用於 ActiveX 控制項專案和 ActiveX DLL 專案了。

製作ActiveX DLL 專案為公寓模型執行緒的程序已經改變,相關資料在為您的專案選擇執行緒模型 中已討論。您不再需要犧牲所有的使用者互談介面(即「執行時無使用者介面」選項),也可擁有公寓模型執行緒 DLL。

當您在執行期建立一個表單的執行個體時,Visual Basic 將遵循和其它私有(private)物件相同的規則。也就是說,新的表單將被建立於執行 New 運算子的執行緒中。如果您以內在的方式建立表單(例如:使用一個宣告為 As New Form1 的變數來存取表單屬性),表單會被建立在執行該程式碼的執行緒中。

請注意  以內在方式建立表單的特殊事項是內建的 ID (例如,Form1);Visual Basic 會為每一表單物件類別維護一個這樣的隱藏且全域的表單變數。因為 Visual Basic 會對每一個「公寓」複製全域資料,每一個執行緒將有其自己的 Form1。為了避免混淆,您最好不要在公寓模型執行緒元件中使用內建 ID。您可以明確地宣告表單變數來達到此目的。

請注意   複製的全域資料意謂著您在標準模組所宣告的 Public 變數,只對某執行緒是全域的;而每一執行緒有該變數的個體。這同時也意謂著 App 物件的屬性,像 App.ThreadID,在每一個執行緒中皆有有不同的個體。

不像表單,ActiveX 控制項是可被客戶端表單所建立和使用的公用(public)物件。一個 ActiveX 控制項的執行個體和使用它的客戶端表單,總是存在於相同的執行緒中。

重要   在公寓模型 DLL 中,對於要求該 DLL 所提供物件的客戶端執行緒而言,一個新的「公寓」會被建立。當客戶端執行緒第一次要求物件時, Sub Main 主程式便會為新的「公寓」而執行一次。DLL 不能建立自己的執行緒。

 

"設計多執行緒跨處理序元件"的變動

您不再需要犧牲所有的使用者互動介面(即「執行時無使用者介面」選項),只為了有多執行緒的執行檔。但有關「獨立的執行緒」和執行緒共用區 (round-robin 依序輪流執行緒)的描述維持不變。

您可以藉由以下步驟來製作具有公寓模型執行緒的 ActiveX 執行檔專案:開啟「專案屬性」對話方塊的「一般」頁籤後,選擇「獨立的執行緒」,或選擇執行緒共用區並設定其大小超過一。

像其它私有物件,表單存在於建立它們的執行緒中。私有物件不能以 CreateObject 函數來建立,所以它們不能用來啟動新的執行緒。

重要   在多執行緒的執行檔中,Sub Main 主程式對每一個新的執行緒會獨立地執行。Visual Basic 並無提供任何方法來決定那一個執行緒先被建立的。

 

使用實例

以下的主題描述您可能會使用公寓模型執行緒的案例

Internet Explorer 4.0 中的公寓模型執行緒控制項
以表單建立 Thread-Safe DLL
建立多執行緒測試應用程式

 

Internet Explorer 4.0 中的公寓模型執行緒控制項

Internet Explorer 4.0 以多執行緒的方式來同時顯示數個視窗。當 Internet Explorer 4.0 上的二個不同視窗顯示相同 ActiveX 控制項時,該控制項必須提供執行個體給每一執行緒。如果這兩個執行個體皆來自 OCX 相同的「公寓」中 (原先的 Visual Basic 5.0 便是如此),其中一個執行個體將因跨執行緒的引用處理而導致不佳的執行效率。

除了執行效率變差之外,當使用於多執行緒應用程式時,單一執行緒控制項會導致駐點(focus)、Tab 和快速鍵等問題。

請用 Visual Basic Version 5.0 SP2 編譯您的 OCX 來增進效率,且移除這些問題。Internet Explorer 4.0 所用的每一個控制項執行個體,將與顯示它的視窗位於相同的執行緒了。這是因為 OCX 已可以對每一客戶端執行緒支援不同的「公寓」之故。

Visual Basic 所附的 ActiveX 控制項已大部份被更新

Visual Basic Version 5.0 SP2 包括大部份原先 VB 所附 ActiveX 控制項之更新版本。這些已更新的控制項目前已是公寓模型執行緒,對於單一執行緒或多重執行緒客戶端,也有相同的執行效能。仍然只是單一執行緒控制項,有 DBGrid、MSChart 和 Visual Basic 5.0 \Tools 目錄中的一些控制項。

以 Visual Basic 製作 ActiveX 控制項

一旦您安裝 Visual Basic Version 5.0 SP2 後,新的 ActiveX 控制項專案將有公寓模型執行緒的預設值。您可以公寓模型執行緒的特性增加到先前的 ActiveX 控制項專案中,所需的方式是改變執行緒模型。請參考為您的專案選擇執行緒模型中的步驟。之後請重新編譯該專案。對於大部分的 ActiveX 控制項專案而言,您只要進行這些步驟即可。

如果您的 ActiveX 控制項專案使用單一執行緒控制項,則您改變執行緒模型為公寓模型執行緒時,將會產生錯誤。由於單一執行緒 ActiveX 控制項會使得多執行緒客戶端發生許多嚴重的問題,Visual Basic 不允許它們使用於具有公寓模型執行緒特性的 ActiveX 控制項中。相關問題在轉換現有的專案中討論。

如果您現有的 ActiveX 控制項使用了單一執行緒控制項,請連絡經銷商以詢問是否可取得公寓模型執行緒的版本。

其它有關公寓模型執行緒 ActiveX 控制項的設計考量在 轉換現有的專案中討論。

 

以表單建立 Thread-Safe DLL

您現在可以在包含表單的 ActiveX DLL 專案中,設定「執行緒模型」選項為公寓模型執行緒。

公寓模型執行緒 DLL 無法建立它們自己的執行緒;當客戶端執行緒第一次要求 DLL 所提供的物件時,一個新的「公寓」將會被建立,且 Sub Main 主程式將會為該「公寓」而執行。所有該客戶端所要求的公用物件,將「居住」於此「公寓」中,且會分享全域資料。這些公用物件所建立的私有物件(包括表單),也同時存在於該「公寓」中。

Visual Basic 並無提供任何方式來讓「公寓」得知其它「公寓」的存在。然而,多執行緒客戶端能夠獲得執行緒 A 中某物件的引用,並將此引用傳給執行緒 B 中的某物件。如果您的 DLL 允許如此做,您應該閱讀線上手冊中有關再次呼叫進入(Reentrancy)的相關資料("Visual Basic 的公寓模型執行緒"),以及本文件的"Visual Basic 的公寓模型執行緒"的變動一節。

重要   由某執行緒所顯示的強制回應表單,不會中斷其它執行緒中的程式碼,由其它的執行緒所顯示的表單也依然可回應使用者的動作。顯示表單即讓出控制權,就像是呼叫 DoEvents,因此可導致物件中的程式碼被再次呼叫進入。

 

建立多執行緒測試應用程式

於Visual Basic 的專業版和企業版安裝 Service Pack 2,可讓您建立多執行緒測試應用程式來應用您的多執行緒控制項。建立一簡易的多執行緒應用程式步驟如下:

  1. 開啟一個新的 ActiveX 執行檔專案,命名預設的物件類別模組為 MainApp。把 MainApp 的 Instancing 屬性設為 PublicNotCreatable。某 MainApp 物件將存在於該應用程式的第一個執行緒,並顯示主要的使用者介面。
  2. 在「專案屬性」對話方塊的「一般」頁籤,於「啟動物件」方塊中選擇「Sub Main」,並在「執行緒模型」方塊選擇「獨立的執行緒」,接著輸入此專案的名稱 。(專案名稱決定了型態程式庫的名稱;如果有二個應用程式有相同的型態程式庫名稱,可能會發生問題。) "ThreadDemo" 是以下範例所使用的專案名稱。在「元件」頁籤上,於「啟動模式」方塊中選擇「獨立的應用程式」。
  3. 增加一個表單,命名為 frmProcess,且設定 Visible ,ControlBox 屬性為 False。這表單將成為一隱藏視窗,其 Sub Main 主程式將用來定義處理序的主要執行緒。這表單不需要任何程式碼。
  4. 增加一個標準模組到專案。在該模組中,填入宣告、Sub Main 程序、EnumThreadWndMain 程序(如下所示)。如同程式註解所言,在應用程式開始和每次您建立新的執行緒時,Sub Main 主程式就會執行。Sub Main 程式碼範例展示了如何辨識第一個執行緒,使您知道何時建立 MainApp。
  5. 增加表單,命名為 frmMTMain。此表單為測試應用程式提供了主要的使用者介面。請在此表單加入「測試應用程式的多個執行個體」標題前的單行宣告指令及 Form_Unload 事件。
  6. 在 MainApp 的 Class_Initialize 事件程序中,加入程式碼來顯示 frmMTMain。程式碼如下所示。
  7. 為了要建立額外的測試執行緒,您的專案中至少要有一個物件類別,其 Instancing 屬性被設為 MultiUse。請增加一個物件類別模組和表單,並插入「建立新的執行緒」標題後的程式碼。因為您為此專案選擇了「獨立的執行緒」,每一在外部建立的公用物件將會啟動新的執行緒。這意謂著您可以利用 CreateObject 函數,來產生 MultiUse 物件類別的執行個體(藉由它的 ProgID),以建立新的執行緒。
  8. 在 frmMTMain 增加程式碼,來產生您所定義的 MultiUse 物件類別的執行個體,以建立新的執行緒。請參閱在標題 "建立新的執行緒"下的程式碼。
  9. 由於發展環境並不支援多執行緒。如果您按下 F5 來執行專案,所有物件將會被建立在相同的執行緒。為了測試多執行緒行為,您必須編譯這個 ActiveX 執行檔專案,再執行結果。

重要   為了確定每一個新的 MultiUse 物件啟動新的執行緒,您必須使用「獨立的執行緒」選項,而非「執行緒共用區」。

在 Sub Main 主程式中決定主要執行緒

Sub Main 主程式會執行每一個新的執行緒,這是因為 Visual Basic 針對每個執行緒(每個「公寓」)皆保留一份全域資料的備份。所以,Sub Main 主程式必須執行每一個新的執行緒,來初始化它的全域資料。這意謂著如果您的 Sub Main 主程式載入一個隱藏式表單或顯示您應用程式的主要使用者介面,那麼,您所建立的每一個新執行緒將有這些被載入的表單備份。

以下的程式碼決定 Sub Main 主程式是否在第一個執行緒中執行,所以,您只可以載入一次隱藏式表單,並且只顯示一次此測試應用程式的主要使用者介面。

' Root value for hidden window caption
Public Const PROC_CAPTION = "ApartmentDemoProcessWindow"

Public Const ERR_InternalStartup = &H600
Public Const ERR_NoAutomation = &H601

Public Const ENUM_STOP = 0
Public Const ENUM_CONTINUE = 1

Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Declare Function EnumThreadWindows Lib "user32" (ByVal dwThreadId As Long, ByVal lpfn As Long, ByVal lParam As Long) As Long

' Window handle retrieved by EnumThreadWindows.
Private mhwndVB As Long
' Hidden form used to identify main thread.
Private mfrmProcess As New frmProcess
' Process ID.
Private mlngProcessID As Long

Sub Main()
    Dim ma As MainApp

    ' Borrow a window handle to use to obtain the process
    '   ID (see EnumThreadWndMain call-back, below).
    Call EnumThreadWindows(App.ThreadID, AddressOf EnumThreadWndMain, 0&)
    If mhwndVB = 0 Then
        Err.Raise ERR_InternalStartup + vbObjectError, , "Internal error starting thread"
    Else
        Call GetWindowThreadProcessId(mhwndVB, mlngProcessID)
        ' The process ID makes the hidden window caption unique.
        If 0 = FindWindow(vbNullString, PROC_CAPTION & CStr(mlngProcessID)) Then
            ' The window wasn't found, so this is the first thread.
            If App.StartMode = vbSModeStandalone Then
                ' Create hidden form with unique caption. 
                mfrmProcess.Caption = PROC_CAPTION & CStr(mlngProcessID)
                ' The Initialize event of MainApp (Instancing =
                '   PublicNotCreatable) shows the main user interface.
                Set ma = New MainApp
                ' (Application shutdown is simpler if there is no
                '   global reference to MainApp; instead, MainApp
                '   should pass Me to the main user form, so that
                '   the form keeps MainApp from terminating.)
            Else
                Err.Raise ERR_NoAutomation + vbObjectError, , _
                    "Application can't be started with Automation"
            End If
        End If
    End If
End Sub

' Call-back function used by EnumThreadWindows.
Public Function EnumThreadWndMain(ByVal hwnd As Long, ByVal lParam As Long) As Long
    ' Save the window handle.
    mhwndVB = hwnd
    ' The first window is the only one required.
    ' Stop the iteration as soon as a window has been found.
    EnumThreadWndMain = ENUM_STOP
End Function

' MainApp calls this Sub in its Terminate event;
'   otherwise the hidden form will keep the 
'   application from closing.
Public Sub FreeProcessWindow()
    Unload mfrmProcess
    Set mfrmProcess = Nothing
End Sub

重要   在未來的 Visual Basic 版本中,可能無法使用如何識別第一個執行緒的技術。

值得注意的是, Sub Main 主程式在執行第一次個執行緒後,將不會對任何執行緒產生動作。當您在新增可建立 MultiUse 物件的程式碼時(以便啟動後續的執行緒),須確認其中包括了設定這些物件初始值的程式碼。

EnumThreadWindows 配合 EnumThreadWndMain 回呼函數,來置放 Visual Basic 所建立供內部使用的某一個隱藏視窗。傳遞此隱藏視窗的視窗控制代碼(handle)給 GetWindowThreadProcessId,它會傳回此 process ID。接著,使用此process ID 來建立由 Sub Main 主程式所載入之隱藏視窗的專用視窗標題。當後續的執行緒偵測到這視窗時,即可知道不需要建立 MainApp 物件了。由於 Visual Basic 並不提供辨識應用程式的主要執行緒之方法,所以需要這種循環式告知的方法。

事件為初始化的 MainApp 物件類別顯示了此測試應用程式的主要表單。MainApp 應該傳遞 Me 來引用主要表單,所以此表單可使得 MainApp 不被中斷。在主要使用者介面,您可以建立所有後續的執行緒。將 MainApp 的 Instance 屬性設定為 PublicNotCreatable,這使您避免顯示兩個主要使用者介面表單的問題。

以下為 MainApp 物件類別和相關表單的簡單範例 (上述之步驟 5 和步驟 6):

' Code for a MainApp class.
Private mfrmMTMain As New frmMTMain

Private Sub Class_Initialize()
    Set mfrmMTMain.MainApp = Me
    mfrmMTMain.Caption = mfrmMTMain.Caption & " (" & App.ThreadID & ")"
    mfrmMTMain.Show
End Sub

Friend Sub Closing()
    Set mfrmMTMain = Nothing
End Sub

Private Sub Class_Terminate()
    ' Clean up the hidden window.
    Call FreeProcessWindow
End Sub

' Code for the form frmMTMain.
Public MainApp As MainApp

Private Sub Form_Unload(Cancel As Integer)
    Call MainApp.Closing
    Set MainApp = Nothing
End Sub

測試應用程式的多重執行個體

隱藏視窗標題包括了 process ID,它使得在執行此測試應用程式的多重執行個體時,不會產生相互干擾的情形。

當您呼叫 CreateObject,您所建立的公用物件類別的執行個體,將會置於目前作用中的應用程式執行個體的一個執行緒上 。這是因為在搜尋正在執行中之可能會支援此物件的其它 Exe 元件之前,CreateObject 總是企圖在目前的應用程式中建立一個物件。

對公寓模型有用的屬性

您可能會發現將 process ID 當成包括 Sub Main 主程式的唯讀屬性模組是個有用的方法:

'This code not required for the test application
Public Property Get ProcessID() As Long
    ProcessID = mlngProcessID
End Property

這允許執行緒中的任何物件經由呼叫不適用的 ProcessID 屬性來取得 process ID。您同時也會發現,這種顯示 Boolean IsMainThread 屬性的方法也是很有用的。

建立新的執行緒

「獨立的執行緒」選項使得外部建立的公用物件(即透過 CreateObject 函數所建立),來啟動新的執行緒。建立新的執行緒,簡單地使用您 MultiUse 物件類別的其中之一個可程式化識別碼(即 ProgID):

'This code not included in the test application
Dim tw As ThreadedWindow
Set tw = CreateObject("ThreadDemo.ThreadedWindow")

變數 tw 引用到新執行緒的物件。所有經由使用 tw 而建立的呼叫到此物件的屬性和方法,將產生跨處理序處理(cross-thread marshaling)的額外負擔。

請注意   不會在新執行緒上建立由 New 運算元所建立的物件。它是存在於與執行 New 運算元相同的執行緒中。請參閱線上手冊的「設計多執行緒跨處理 序元件」和 「Visual Basic 元件如何建立物件」。

在其它所有執行緒都結束前,為了確保 MainApp 不會中斷,您可以給每一個公用物件類別一個 MainApp 屬性。當一個物件在新執行緒上建立一個 MultiUse 物件時,它會傳遞給這個新物件一個 MainApp 物件的引用,並視為初始化的一部份。(您同時可以傳遞給 MainApp 一個新物件的引用,如此一來,MainApp 便有所有控制執行緒的物件引用之集合物件;然而,請記得這將會建立成循環式引用。請參閱線上手冊的「處理循環引用的問題」。)

當您要使用一個控制執行緒的物件類別來顯示表單時,您應提供一個初始化方法(不要與初始化事件混淆)或使用 Show 方法來顯示表單。當您建立物件類別的執行個體時,不要在 Class_Initialize 事件程序中顯示表單,否則可能會引起時間性錯誤。以下為 MultiUse ThreadedWindow 物件類別的程式碼和其表單 frmThreadedWindow 的簡單範例:

'Code for a MultiUse ThreadedWindow class.
Private mMainApp As MainApp
Private mfrm As New frmThreadedWindow

Public Sub Initialize(ByVal ma As MainApp)
    Set mMainApp = ma
    Set mfrm.ThreadedWindow = Me
    mfrm.Caption = mfrm.Caption & " (" & App.ThreadID & ")"
    mfrm.Show
End Sub

Friend Sub Closing()
    Set mfrm = Nothing
End Sub

'Code for the form frmThreadedWindow.
Public ThreadedWindow As ThreadedWindow

Private Sub Form_Unload(Cancel As Integer)
    Call ThreadedWindow.Closing
    Set ThreadedWindow = Nothing
End Sub

以下的程式碼片段告訴您如何初始化 ThreadedWindow 物件:

'Code for the test application's main form (frmMTMain).
Private Sub mnuFileNewTW_Click()
    Dim tw As ThreadedWindow
    Set tw = CreateObject("ThreadDemo.ThreadedWindow")
    ' Tell the new object to show its form, and
    '   pass it a reference to the main
    '   application object.
    Call tw.Initialize(Me.MainApp)
End Sub

如果您有很多可以控制執行緒的物件類別,您可以經由定義 IApartment 介面,將您的程式碼設計的較為通用,並且包括 Initialize 方法。當您在每個物件類別中使用 IApartment 時,您可以對此物件類別提供合適的 Initialize 方法程式碼 。以下是您建立執行緒的程式碼:

'This code not required for the test application
Private Sub mnuFileNewObject_Click(Index As Integer)
    Dim iapt As IApartment
    Select Case Index
      Case otThreadedWindow
        Set iapt = CreateObject("ThreadDemo.ThreadedWindow")
      ' (other cases?)
    End Select
    ' Common code to initialize objects.
    Call iapt.Initialize(MainApp)
End Sub

請注意   經由在不同的型態程式庫中定義介面,您可以使得一個 IXxxxApartment 介面是多執行緒應用程式所特定的。在 ActiveX 執行檔專案中,設定該型態程式庫的引用。

維護執行緒物件的引用

為了確認多執行緒應用程式適當的結束動作,您必須要小心地追蹤所有您所用來建立和控制執行緒的 MultiUse 物件引用。

明確定義您的物件生命週期目標。舉例而言,考慮顯示表單的 MultiUse 物件之生命週期目標。管理物件生命週期最簡單的方法是以物件傳遞一個 Me 的引用給表單;接著,此表單便維持著物件的生命。當使用者關閉此表單時,此表單的 Unload 事件必須將所有 MultiUse 物件的引用設定為 Nothing,使得物件能中斷以及接著清除它所使用之表單的引用。(您可以發現指定 MultiUse 物件一個 Friend 方法很有用的,它用來清除表單的引用和所有其它內部物件的引用;表單的 Unload 事件可以呼叫此方法。)

如果控制執行緒的物件使用 New 運算元在執行緒上建立額外的物件時,請確定您清除對這些額外物件的引用。在所有建立在執行緒上之物件的引用都被釋放前,無法關閉此執行緒。開啟執行緒會浪費系統資源。

Friend 方法無法使用於跨執行緒

因為 Friend 屬性和方法不是一個物件類別之公用介面的一部份,所以您不能從另一個執行緒來呼叫它們。在物件之間的跨執行緒呼叫,僅適於宣告為 Public 的屬性和方法。

再次呼叫進入(Reentrancy)

若物件的方法是經由呼叫 DoEvents、顯示強制回應(modal)表單或在另一個執行緒上對物件做次階層呼叫而產生的,那麼在第一次呼叫完成以前,可以透過第二個呼叫者進入此方法中的程式碼。如果此方法使用或改變了屬性值或模組層次變數,這可能會導致不正確的物件內部狀態。為避免再次呼叫進入,您可以:

非同步作業

Visual Basic 無法提供交叉式執行(fork execution)的處理方式-也就是說,用一個執行緒起始一個新執行緒的方法之呼叫,且立刻在原始執行緒重新繼續處理。藉由原始方法的呼叫來開啟計時器,然後立刻傳回的方式,您也可以在您測試應用程式中模擬此行為。當計時器事件發生時,您可以將計時器關閉及進行非同步處理。有關此技術,請參閱線上手冊的「非同步回呼和事件」,在 Coffee 應用程式範例以及線上手冊中皆有示範說明 (請參閱「建立 ActiveX EXE 元件」)。

使用多執行緒測試應用程式

為了測試您的公寓模型執行緒元件,您必須編譯多執行緒測試應用程式,因為 Visual Basic 開發環境目前不支援多重執行緒的執行。如果您有 Visual Studio,您會發現用它來進行編譯偵錯測試應用程式,取得原始程式碼偵錯資訊是很有用的,所以您可以使用 Visual Studio 偵錯工具。

 

Script 中 ActiveX 控制項的使用安全性說明

Visual Basic Version 5.0 SP2 中,兩個公寓模型執行緒控制項 - Common Dialog 控制項和 Toolbar 控制項,現在支援 ActiveX IObjectSafety 介面。當這些控制項使用於強迫性安全式 Script 的環境時行(如 Internet Explorer),它們將會被標記為「Script 可安全使用」;然而,這些控制項的某些特性將會被暫止,以確保它們可安全地使用在 Script 中:

 

包裝清單

在 Visual Basic Version 5.0 SP2 包括以下的檔案: 

asycfilt.dll
c2.exe
comct232.dep
comct232.ocx
comctl32.dep
comctl32.ocx
comdlg32.dep
comdlg32.ocx
dbgrid32.dep
dbgrid32.ocx
dblist32.dep
dblist32.ocx
mci32.dep
mci32.ocx
mscdrun.dep
mscdrun.dll
mscomm32.dep
mscomm32.ocx
mscondes.dll
msflxgrd.dep
msflxgrd.ocx

msinet.ocx
msinet.dep
msmapi32.dep
msmapi32.ocx
msmask32.dep
msmask32.ocx
msrdc20.dep
msrdc20.ocx
msrdo20.dep
msrdo20.dll
msstkprp.dll
msvbvm50.dll
mswinsck.dep
mswinsck.ocx
oleaut32.dll
olepro32.dll
picclp32.dep
picclp32.ocx
readme.wri
richtx32.dep
richtx32.ocx

setup1.bas
setup1.exe
setupwiz.exe
stdole2.tlb
sysinfo.dep
sysinfo.ocx
tabctl32.dep
tabctl32.ocx
vb5.exe
vb5dep.ini
vb5ide.dll
vb5sp2.htm
vb5sp2.wri
vba332me.dll
vba5.dll

 

下列檔案僅適用於 Alpha 系統:
adme.dll
dtccm.dll
dtctrace.dll
dtcutil.dll
msdtcprx.dll