|
Microsoft Visual Basic 5.0 Service Pack 2 发行注释 |
|
© 1996-1997 Microsoft Corporation
Visual Basic 5.0 Service Pack 2 是对Visual Basic专业、企业和控件创建版(Control Creation Edition,没有中文版)的更新。它使得带有用户界面成分如:窗体和控件的Visual Basic 工程可进行单元模式线程化(apartment-model threading,该术语在中文版Visual Basic 5.0中曾译为“房间模式线程化”)。同时还修正了 VB5.0 中的几个缺陷。(在Knowledge Base Web站点
http://www.microsoft.com/kb/default.asp 上查找 VB4FIXLISTSP。)在您的有许可权的Visual Basic上运行Service Pack 2,允许您创建在多线程客户端,如 Internet Explorer4.0,能够运行良好的 ActiveX™ 控件和ActiveX文件。若您有 Visual Basic 的专业版或企业版,还能创建:
单元模型线程化(apartment-model threading)的增强是 Visual Basic 5.0 Service Pack 2 的唯一特点
这些发行注释包含对 Microsoft® Visual Basic® 5.0的帮助和联机手册的增补信息。更详细的信息,请访问Microsoft Visual Basic Web 站点
http://www.microsoft.com/vbasic/.对单元模型线程化(Apartment-Model Threading)的变更的概述
为工程选择线程模型
单元模型线程化(Apartment-Model Threading)特性的限制
转换现存工程
“ Visual Basic 的单元模型线程化(Apartment-Model Threading)”的变更
“设计线程安全(Thread-Safe) DLLs”的变更
“设计多线程进程外部件”的变更
用于 Internet Explorer 4.0的单元线程(Apartment-Threaded)控件
创建一个带有窗体的线程安全(Thread-Safe) DDL
创建一个多线程测试应用程序
对 ActiveX Controls设置脚本(Scripting)安全性注意事项
由Visual Basic 5.0 ServicePack 2所创建的工程,可充分利用单元模型线程化(Apartment-Model Threading),而无须抑制可视化元素如:窗体和控件。应用Service Pack 2可使窗体、UserControls、UserDocuments和ActiveX 设计器线程安全(thread-safe)。 Service Pack 2 包括:
注意 ActiveX支持的代码,现在是单元模型线程安全的(apartment-model thread-safe),但并不能保证一个特定的设计器是线程安全的(thread-safe)。如果您使用的是第三方的设计器,则须检查您的代理商。
本文档中仅有影响线程安全(thread-safe) ActiveX 控件工程的部分适用于控件创建版(Control Creation Edition)。
如果您用控件创建版(Control Creation Edition)来创建单元线程(apartment-threaded) ActiveX 控件,则必须使用多线程的客户端,如Internet Explorer 4.0来检测您的控件的多线程行为。不能使用控件创建版(Control Creation Edition)创建多线程的测试客户端。
Service Pack 2 改变了“工程属性”对话框的“通用”选项卡中的选项。应用 Service Pack 2 后,“无用户界面执行”选项将不再和“线程模型”联结在一起提供给您的工程。可以为“线程模型”选项选择一个设置值而不必标记您的工程为“无用户界面执行”。
为 ActiveX DLL、ActiveX Exe 或 ActiveX 控件工程设置线程模型
对 ActiveX DLL 和 ActiveX 控件工程,选择单元线程(Apartment Threaded)或单线程都可以。
对于ActiveX Exe工程,既可定义每一个新对象在一新线程上被创建(“每个对象的线程”),或限定您的部件为一固定大小的线程缓冲池。如果线程缓冲池大小为1,则对象为单线程,更大的线程缓冲池确定工程为单元线程(apartment-threaded)。
注意 改变现存工程的线程模型时,如果工程使用了单线程ActiveX 控件,会发生错误。Visual Basic在单元线程(apartment-threaded)工程中禁止使用单线程控件。如转换现存工程中所述。
注意 如果指定一个 ActiveX Exe 工程为“每个对象的线程”(或大于1的线程缓冲池)时,只有外部创建的对象创建于新线程上。(请参阅联机手册中的“设计多线程进程外部件”)。对于 ActiveX DLL 和 ActiveX 控件工程,“每个对象的线程”和“线程缓冲池”是不可用的,因为线程的创建是由客户应用程序控制的。
重点 对于专业版和企业版的使用者,选择“每个对象的线程”或“线程缓冲池”的重要性将在联机手册里的“设计多线程进程外部件”里详尽讨论。
Service Pack 2 并未改变“无用户界面执行”选项的功能。“无用户界面执行”仍允许您创建无须操作者干预就能在网络服务器上运行的部件。Service Pack 2 所做的唯一改变是选择“无用户界面执行”不会影响部件的线程模型。
以下限制适用于Visual Basic 的所有版本
一旦应用了 Visual Basic 5.0 Service Pack 2,就可以通过改变“线程模型”选项来添加单元线程(apartment threading)到现存的工程,如
为工程选择线程模型中所述,并重新编辑工程。对于许多工程,所有您要做的就是这些。如果一个现存ActiveX DLL、ActiveX EXE、或ActiveX控件工程使用单线程构成控件,试图把“线程模型”改为单元线程(Apartment Threaded)就会出错。由于单线程ActiveX 控件在多线程客户端所引起的问题的数目和严重性,Visual Basic不允许ActiveX部件工程使用它们。
如果现存工程采用了单线程控件,请与代理商联系,看看是否有可用的单元线程版本。
通过手工编辑 .vbp 文件,可以“欺骗” Visual Basic 在单元线程(apartment-threaded)工程里使用单线程控件。但是不要这样做。由单线程 ActiveX 控件引起的问题包括:
重点 在使用 Visual Basic 或其他开发工具建立的多线程部件或应用程序中,单线程控件可能会引起这样和那样的问题。
进程内部件提供的对象创建于客户端线程;您的 DLL 或 OCX 不能创建其自己的线程。当一个客户端线程第一次创建您的部件提供的对象的实例时,会为该线程创建一个新的“单元”(apartment),并且 Sub Main 会为该新“单元”(apartment)执行。所有您的部件为该客户端线程提供的对象将驻留在同一个“单元”(apartment)。
如果您已经设计好部件,并且所有的类的实例共享一些公用全局数据,那么现在这些数据只能被那些恰好在同一线程的对象所共享。如果您的部件中有访问数据库的全局代码,那么现在该访问将在每个线程中独立发生。
例如,假设一个多线程的客户端在线程 A 的一个窗体中显示一个 Widget 控件的实例,在线程 B 的一个窗体中显示该控件的两个实例。则该控件的这些实例将位于两个“单元”(apartment)中,每个实例都带有全局变量的复本。将为每个“单元”(apartment)执行一次 Sub Main。在线程 B 中的两个控件将共享全局声明,与线程 A 中的控件的全局声明是分开的。
其他的设计考虑将在本文档中的
“Visual Basic 中的单元模型线程化(Apartment-Model Threading)”的变更 和 “设计线程安全(Thread-Safe) DLLs”的变更及 Visual Basic 5.0 联机手册的相关主题中讨论。在单线程的和单元线程(apartment-threaded)的进程外部件之间,最重要的差别是为每个线程复制所有的全局数据(包括 App 对象的属性)。意味着每创建一个新的线程,Sub Main 将运行一次。
其他有关进程外部件的设计考虑将在本文档中的
“Visual Basic 中的单元模型线程化(Apartment-Model Threading)”的变更 和 “设计多线程的进程外部件”的变更及Visual Basic 5.0 联机手册的相关主题中讨论。
下面的主题描述对于给出的Visual Basic 5.0 联机手册的主题的变更:
“Visual Basic 中的单元模型线程化(Apartment-Model Threading)”的变更
“设计线程安全(Thread-Safe) DLLs”的变更
“设计多线程的进程外部件”的变更
如果您有 Visual Basic 专业版或企业版,在联机手册中,可以在目录区定位这些主题:
部件工具指南
创建 ActiveX 部件
建立代码部件
可扩展性和多线程
注意 控件创建版中不包含联机手册的浏览器。上面所列出的主题不包含在可下载的用于控件创建版的 Visual Basic 5.0 文档部分。然而,控件创建版的用户会对包含在下面两个主题中的有关重入和设计线程安全部分的材料感兴趣。
联机手册中原有的主题中的解释是,Visual Basic 为每个线程保持一份全局数据的复本。这样的一个副作用是为每个新的“单元”(apartment)(也就是说,为每个新的线程)执行一次 Sub Main,这一点在联机手册中并未提及。否则,就无法为每个线程初始化全局数据。对于这一点,在下面的
“设计线程安全(Thread-Safe) DLLs”的变更 和 “设计多线程的进程外部件”的变更, 中有更详细的讨论。已经不再需要为了使用单元线程化(apartment threading)而将部件标记为“无用户界面执行”。现在,“无用户界面执行”是“工程属性”对话框的“通用”选项卡的一个独立选项,如前面的
为工程选择线程模型,中所述。原有主题的描述是,当进行线程间调用时,所调用的方法在重入至该方法未被移交(例如,通过调用 DoEvents)期间将被保护。有必要强调的是,下面的情况也可以移交一个方法:通过自身的线程间或进程间方法调用;通过显示一个窗体。
现在的联机手册中,同 ActiveX DLL 工程一样,对于 ActiveX 控件工程也有相应的描述。
使一个ActiveX DLL 工程为单元线程(apartment-threaded)的过程已经改变,如前面的
为工程选择线程模型中所述。已不再需要为生成单元线程(apartment-threaded) DLL 而屏蔽所有的用户交互(“无用户界面执行”选项)。在运行时创建一个窗体的实例,Visual Basic 遵循其他私有对象所使用的规则。即,新窗体创建于执行新操作者的线程。如果隐含地创建一个窗体(例如,通过使用声明为 As New Form1 的变量访问一个窗体的属性),则新窗体创建于执行代码的线程。
注意 隐含窗体创建的一个特定原因是预先声明的 ID (例如,Form1),它是 Visual Basic为每个窗体类保持的一个隐含的全局窗体变量。因为 Visual Basic 为每个“单元”( apartment)复制一份全局数据,所以每个线程都有各自的 Form1。为避免混淆,应避免在单元线程(apartment-threaded)部件中使用预先声明的 IDs,这可以通过显示地声明自己的窗体变量实现。
注意 重复的全局数据,意味着在标准模块中声明为 Public 的变量仅对该线程是全局的;每个线程都有该变量的一个实例。同时,还意味着 App 对象的属性,如 App.ThreadID,对于每个线程都有各自的实例。
与窗体不同,ActiveX 控件是公有对象,可以被客户端窗体创建和使用。ActiveX 控件的实例一般驻留于使用它的客户端窗体的线程中。
重点 对于单元模型(apartment-model) DLL,为每个请求该 DLL 提供的对象的客户端线程创建一个新的“单元”(apartment)。当一个客户端线程第一次请求这样的对象时,为新“单元”(apartment)执行 Sub Main。DLL 不能创建自身的线程。
已不再需要为生成多线程 Exe 而屏蔽所有的用户交互(“无用户界面执行”选项)。对“每个对象的线程”和“线程缓冲池”(循环的线程(round-robin threading))的描述没有变化。
通过打开“工程属性”对话框的“通用”选项卡,选择“每个对象的线程”,或选择“线程缓冲池”并设置大于1的缓冲池大小,可以使 ActiveX Exe 工程单元线程化(apartment-threaded)。
与其他私有对象一样,窗体驻留于创建它们的线程中。私有对象不能使用 CreateObject 函数创建,所以不能用于启动新线程。
重点 在一个多线程可执行程序中,对于每个新线程,Sub Main 独立执行。Visual Basic 无法决定先创建哪个线程。
下列主题描述使用单元模型线程化(apartment-model threading)的方案。
用于 Internet Explorer 4.0 的单元线程(Apartment-Threaded)控件
创建一个带有窗体的线程安全(Thread-Safe) DLL
创建一个多线程测试应用程序
Internet Explorer 4.0使用多个执行线程显示窗口。如果 Internet Explorer 4.0 中的两个不同窗口显示同一 ActiveX 控件的实例,该 OCX 必需为每个线程提供一个实例。如果两个实例由 OCX 的同一“单元”(apartment)提供(如 Visual Basic 5.0 的情况),其中某一控件实例因为线程间调度而性能下降。
除性能下降外,在多线程应用程序中使用单线程控件还会引起诸如焦点、tab 键移动、和加速键问题。
使用 Visual Basic 5.0 Service Pack 2 编译您的 OCX 会提高性能,并且没有以上的问题。每个 Internet Explorer 4.0 使用的控件实例运行于显示这些控件的窗口的线程中,这是因为该 OCX 支持每个客户端线程一个独立的“单元”(apartment)。
Visual Basic 5.0 Service Pack 2 包含大多数 Visual Basic 5.0 的 ActiveX 控件的新版本。升级的控件是单元模型线程化(apartment-model threaded)的,在单线程或多线程客户端都会表现出色。仍然是单线程的控件包括 DBGrid、 MSChart、 以及 Visual Basic 5.0 的 Tools 目录下的继承的控件。
一旦您开始使用 Visual Basic 5.0 Service Pack 2,新的 ActiveX 控件工程缺省为单元模型线程化(apartment-model threading)的。通过改变线程模型,可以添加单元线程(apartment threading)到现存的 ActiveX 控件工程,如
为工程选择线程模型中所述,然后重新编译该工程。对于许多 ActiveX 控件工程,所有您要做的就是这些。如果您的 ActiveX 控件工程使用了单线程构成控件,则试图改变其线程模型为“单元线程”(Apartment Threaded)会引起错误。因为多线程客户端中的单线程 ActiveX 控件所引起问题的数目和严重性,Visual Basic 不允许其作为单元线程 ActiveX 控件的构成。这将在
转换现存工程中讨论。如果您的 ActiveX 控件使用了单线程构成控件,请与该单线程控件的代理商联系,看看是否有可用的单元线程版本。
其他有关单元线程(apartment-threaded) ActiveX 控件的设计考虑将在
转换现存工程中讨论。
现在,您可以在包含窗体的 ActiveX DLL 工程中设置“线程模型”选项为“单元线程”(Apartment Threaded)。
单元线程(Apartment Threaded) DLLs 不能创建其自身的线程;一个客户端线程第一次请求由您 DLL 提供的对象时,将创建一个新的“单元”(apartment),并且为该“单元”(apartment)执行 Sub Main。所有该客户端请求的公有对象将驻留在同一“单元”(apartment),共享全局数据。由公有对象所创建的任何私有对象(包括窗体)同样驻留在该“单元”(apartment)。
Visual Basic 不提供“单元”(apartment)之间互相识别的机制。然而,一个多线程客户端可以获得对线程 A 中一个对象的引用,并且把该引用传递给线程 B 中的对象。如果您的 DLL 允许这样,您应该阅读联机手册中“Visual Basic 中的单元模型线程化(Apartment-Model Threading)”的有关重入的信息,以及本文档中的
“Visual Basic 中的单元模型线程化(Apartment-Model Threading)”的变更。重点 一个线程中显示的有模式窗体,不会阻塞其他线程的代码的执行,并且对于其他线程中的窗体不是有模式的。显示一个窗体会移交控件,就如调用 DoEvents 一样,并且可能会引起重新进入某一对象中的代码。
对 Visual Basic 专业版和企业版应用 Service Pack 2 ,允许创建多线程的测试应用程序来调试您的多线程控件。创建一个简单的多线程应用程序的步骤如下:
重点 为了确保每个新的 MultiUse 对象启动一个新的线程,必须使用“每个对象的线程”而不是“线程缓冲池”。
对于每个新线程,Sub Main 都执行。 这是因为 Visual Basic 为每个线程(每个“单元”(apartment))维护全局数据的独立复本。为了初始化线程的全局数据,Sub Main 必须执行。这意味着如果“Sub Main”加载隐藏的窗体、或显示应用程序的主用户界面,则对于每个新创建的线程这些窗体的新的复本将被加载。
下列代码决定了在第一线程中“Sub Main”是否在执行,这样可以仅加载隐藏窗体一次,并仅显示测试应用程序的主用户界面一次。
'隐藏窗口标题的根值
Public Const PROC_CAPTION = "ApartmentDemoProcessWindow"
Public Const ERR_InternalStartup = &H600
Public Const ERR_NoAutomation = &H601
Public Const ENUM_STOP = 0
Public Const ENUM_CONTINUE = 1
Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Declare Function EnumThreadWindows Lib "user32" (ByVal dwThreadId As Long, ByVal lpfn As Long, ByVal lParam As Long) As Long
' 通过 EnumThreadWindows 检索窗口句柄。
Private mhwndVB As Long
' 用于标识主线的隐藏窗体。
Private mfrmProcess As New frmProcess
' 过程 ID.
Private mlngProcessID As Long
Sub Main()
Dim ma As MainApp
' 借用窗口句柄,用于取得进程
' ID (参阅下面的 EnumThreadWndMain 回调)。
Call EnumThreadWindows(App.ThreadID, AddressOf EnumThreadWndMain, 0&)
If mhwndVB = 0 Then
Err.Raise ERR_InternalStartup + vbObjectError, , "Internal error starting thread"
Else
Call GetWindowThreadProcessId(mhwndVB, mlngProcessID)
' 过程 ID 使得隐藏的窗口标题唯一。
If 0 = FindWindow(vbNullString, PROC_CAPTION & CStr(mlngProcessID)) Then
' 窗口没有找到,所以这是第一线程。
If App.StartMode = vbSModeStandalone Then
' 创建带有唯一标题的隐藏窗体。
mfrmProcess.Caption = PROC_CAPTION & CStr(mlngProcessID)
' MainApp 的(Instancing =
' PublicNotCreatable) 初始化事件,显示主用户界面。
Set ma = New MainApp
' (如果没有对 MainApp 的全局引用,
' 关闭应用程序相对比较简单;否则, MainApp
' 应该将“Me” 传递到主用户窗体,则该窗体
' 保持 MainApp,使其不被终止。)
Else
Err.Raise ERR_NoAutomation + vbObjectError, , _
"Application can't be started with Automation"
End If
End If
End If
End Sub
' EnumThreadWindows 使用的回调函数。
Public Function EnumThreadWndMain(ByVal hwnd As Long, ByVal lParam As Long) As Long
' 保存窗口句柄。
mhwndVB = hwnd
' 仅需要第一个窗口。
' 找到窗口,立即停止循环。
EnumThreadWndMain = ENUM_STOP
End Function
' MainApp的 Terminate 事件中调用该 Sub;
' 否则隐藏的窗体将保持应用程序
' 使它不被关闭。
Public Sub FreeProcessWindow()
Unload mfrmProcess
Set mfrmProcess = Nothing
End Sub
重点
标识第一线程的技术可能在 Visual Basic 的未来版本上不能工作。注意“Sub Main”对于第一线程之后的任何线程不采取动作。当添加创建MultiUse 对象的代码时(为了启动后来的线程),要确定包含初始化这些对象的代码。
EnumThreadWindows 使用时带有回调,EnumThreadWndMain,是为了定位 Visual Basic 为内部使用所创建的一个隐藏窗口。该隐藏窗口的窗口句柄被传给返回进程 ID 的 GetWindowThreadProcessId。对于“Sub Main”加载的隐藏窗体(frmProcess),进程 ID 用于创建该隐藏窗体的唯一的标题。后来的线程检测该窗体,并得出无需创建 MainApp 对象的结论。这些旋回过程是必须的,因为 Visual Basic 不提供识别应用程序主线程的方法。
MainApp 类,在它的 Initialize 事件中,显示测试应用程序的主窗体。MainApp 应该传递它的“Me”引用到主窗体,则该窗体将保持 MainApp,使其不被终止。从主用户界面可创建所有后来的线程。设置 MainApp 的 Instancing 属性为 PublicNotCreatable,可以帮助您避免显示两个主用户界面窗体。
一个 MainApp 类的简单示例及它相关的窗体(上面的步骤5和6)可能看起来象这样:
' MainApp 类代码。
Private mfrmMTMain As New frmMTMain
Private Sub Class_Initialize()
Set mfrmMTMain.MainApp = Me
mfrmMTMain.Caption = mfrmMTMain.Caption & " (" & App.ThreadID & ")"
mfrmMTMain.Show
End Sub
Friend Sub Closing()
Set mfrmMTMain = Nothing
End Sub
Private Sub Class_Terminate()
' 清除隐藏窗口。
Call FreeProcessWindow
End Sub
' 窗体 frmMTMain 的代码。
Public MainApp As MainApp
Private Sub Form_Unload(Cancel As Integer)
Call MainApp.Closing
Set MainApp = Nothing
End Sub
在隐藏窗口标题中包括进程 ID,则允许运行测试应用程序的多个实例,且不会互相干扰。
调用 CreateObject 时,所创建的公共类的实例将在当前应用程序实例的线程上。这是因为在查找其它可能供给对象的正运行的 Exe 部件之前,CreateObject 总是尝试着在当前应用程序中创建对象。
您可能发现将进程 ID 显露为包含“Sub Main”模块的只读属性是有用的:
'测试应用程序不需要该代码
Public Property Get ProcessID() As Long
ProcessID = mlngProcessID
End Property
这就允许线程中的任何对象通过调用非限定的 ProcessID 属性得到进程标识符。您也可能发现以这种方式显露一个 Boolean IsMainThread 属性很有用。
“每个对象的线程”选项使每一外部创建的公共对象*即采用 CreateObject 方式创建的* 在一个新线程上启动。要创建一个新线程,仅需使用您的一个 MultiUse 类的程序ID (ProgID) 就可:
'该代码不包括在测试应用程序中。
Dim tw As ThreadedWindow
Set tw = CreateObject("ThreadDemo.ThreadedWindow")
变量 tw 包含一个对新线程上对象的引用。所有对由 tw 生成的对象的属性和方法的调用均受额外的全部线程间调度的限制。
注意 采用 New 操作符创建的对象不是创建于新线程上的。它驻留在 New 操作符执行的线程上。参见“联机手册”中“多线程进程外部件的设计” 和 “在 Visual Basic 部件中如何创建对象”。
为确保直到所有其他线程结束 MainApp 才终止,可以给每个公共类一个 MainApp 属性。 当对象在一个新线程上创建 MultiUse 对象时,它可以将对MainApp对象的一个引用做为初始化进程的一部分传递给新对象。(也可以传递一个对新线程的引用给 MainApp,这样 MainApp 就有了一个对所有控制线程对象的引用的集合,然而,要注意这样将创建循环引用。 参见“联机手册”中 “处理循环引用”。)
如果希望一个控制线程的类显示窗体,您应当为其提供一个显示窗体的 Initialize 方法 (不要同 Initialize 事件混淆) 或 Show 方法。 不要在 Class_Initialize 事件过程中显示窗体,因为这样会在创建该类的实例时引起计时错误。 在一个非常简单的例子中, MultiUse ThreadedWindow 类的代码和其窗体, frmThreadedWindow,可能看起来象这样:
' MultiUse ThreadedWindow 类的代码。
Private mMainApp As MainApp
Private mfrm As New frmThreadedWindow
Public Sub Initialize(ByVal ma As MainApp)
Set mMainApp = ma
Set mfrm.ThreadedWindow = Me
mfrm.Caption = mfrm.Caption & " (" & App.ThreadID & ")"
mfrm.Show
End Sub
Friend Sub Closing()
Set mfrm = Nothing
End Sub
' frmThreadedWindow窗体的代码。
Public ThreadedWindow As ThreadedWindow
Private Sub Form_Unload(Cancel As Integer)
Call ThreadedWindow.Closing
Set ThreadedWindow = Nothing
End Sub
如下代码片段表明您可能如何初始化 ThreadedWindow 对象:
'测试程序主窗体 (frmMTMain) 代码。
Private Sub mnuFileNewTW_Click()
Dim tw As ThreadedWindow
Set tw = CreateObject("ThreadDemo.ThreadedWindow")
'告知新对象显示其窗体并将对主应用
' 程序对象的一个引用
' 传递给它。
Call tw.Initialize(Me.MainApp)
End Sub
如果有多个可以控制线程的类,可以通过定义一个包含 Initialize 方法的 Iaapartment 接口使您的代码更加通用。在每个类中实现 IApartment 时,您可为该类提供适当的 Initialize 方法代码。线程创建代码可能看上去会象这样:
'测试应用程序不需要该代码
Private Sub mnuFileNewObject_Click(Index As Integer)
Dim iapt As IApartment
Select Case Index
Case otThreadedWindow
Set iapt = CreateObject("ThreadDemo.ThreadedWindow")
' (其他 cases*)
End Select
' 初始化对象的普通代码。
Call iapt.Initialize(MainApp)
End Sub
注意
通过在独立的类型库中定义 IxxxxApartment 接口,可以使该接口只能被多线程应用程序识别。在 ActiveX Exe 工程中,设置对该类型库的引用。为确保对多线程应用程序的正常关闭,您必须对用来创建和控制线程的MultiUse对象的所有引用保持紧密跟踪。
明确定义您的对象存活期目标。例如,考虑显示一个窗体的 MultiUse 对象的情况。管理对象存活期最简便的方法是让对象传递给窗体一个 Me 引用; 窗体就会保持对象存活。当用户关闭窗体时,窗体的 Unload 事件必须将对 MultiUse 的所有引用设为 Nothing,这样对象就可终止,并且反过来清除对窗体的引用。 (您会发现给 MultiUse 对象一个清除对窗体和所有其他内部对象引用的 Friend 方法非常有用;窗体的 Unload 事件可以调用该方法。)
如果控制线程的对象在该线程上使用 New 操作符创建了一个附加对象,确保您清除了对所有那些对象的引用。直到对创建于该线程上的对象的所有引用均被释放之后,该线程才能关闭。打开线程会浪费系统资源。
因为 Friend 属性和方法不是类的公共接口的一部分,所以不能从另外一个线程调用它们。对象的线程间调用仅限于那些声明为 Public 的属性和方法。
如果通过调用 DoEvents、显示一个有模式窗体、或对另一个线程上的对象做了一个辅助调用,导致一个对象方法的移交,则该方法中的代码可以在第一次调用完成前由第二个调用者进入。如果这样的一个方法使用或改变了属性值或模块级变量,将会导致对象的非法内部状态。为防止重入,您可以:
Visual Basic 不提供分支执行方法(让一个线程在一个新线程上初始化一个方法调用并立即恢复原线程上的处理)。通过让原始方法打开一个计时器并立刻返回的方法,可以在您的测试应用程序中模拟这一行为。当计时事件发生时,您可关掉计时器并执行异步处理。这一技术在“联机手册”的“异步回调和事件” 中讲到,并在“联机手册”(参见 “创建 ActiveX Exe 部件”)和Coffee示例应用程序中演示。
为测试您的单元线程(apartment-threaded)部件,您必须编译多线程测试应用程序,因为 Visual Basic 开发环境目前不支持多线程执行。如果您有 Visual Studio,那么带有调试信息编译测试应用程序对本机代码的调试非常有用,这样可以使用 Visual Studio 的调试器。
Visual Basic 5.0 Service Pack 2 包括的单元线程(apartment-threaded)控件中的两个,Common Dialog 控件和 Toolbar 控件,现在支持 ActiveX IObjectSafety 接口。当这些控件用在设置了脚本安全性的环境中,例如Internet Explorer,它们将被标记为“设置脚本安全性”;然而,为了使其成为“设置脚本安全性”,这些控件的某些特性将无效:
以下文件包括在 Visual Basic 5.0 Service Pack 2 中:
|
comct232.ocx |
msmask32.ocx |
msvbvm50.dll |